dnl Process this file with autoconf to create configure.
dnl $Id: configure.in,v 1.41 2003/03/06 04:29:23 chipx86 Exp $

AC_INIT(config.h.in)

dnl ################################################################
dnl # Version information
dnl ################################################################
LIBCOMPREX_MAJOR_VERSION=0
LIBCOMPREX_MINOR_VERSION=3
LIBCOMPREX_MICRO_VERSION=3
LIBCOMPREX_DEVEL_VERSION=0

LIBCOMPREX_VERSION=$LIBCOMPREX_MAJOR_VERSION.$LIBCOMPREX_MINOR_VERSION.$LIBCOMPREX_MICRO_VERSION

if test "x$LIBCOMPREX_DEVEL_VERSION" != "x0"; then
	if test "x$LIBCOMPREX_MICRO_VERSION" = "x0"; then
		LIBCOMPREX_MICRO_VERSION=$LIBCOMPREX_DEVEL_VERSION
		LIBCOMPREX_VERSION=$LIBCOMPREX_MAJOR_VERSION.$LIBCOMPREX_MINOR_VERSION.$LIBCOMPREX_DEVEL_VERSION
	else
		LIBCOMPREX_VERSION=$LIBCOMPREX_VERSION.$LIBCOMPREX_DEVEL_VERSION
	fi
fi

AC_DEFINE_UNQUOTED(LIBCOMPREX_MAJOR_VERSION, $LIBCOMPREX_MAJOR_VERSION,
	[libcomprex major version.])
AC_DEFINE_UNQUOTED(LIBCOMPREX_MINOR_VERSION, $LIBCOMPREX_MINOR_VERSION,
	[libcomprex minor version.])
AC_DEFINE_UNQUOTED(LIBCOMPREX_MICRO_VERSION, $LIBCOMPREX_MICRO_VERSION,
	[libcomprex micro version.])
AC_DEFINE_UNQUOTED(LIBCOMPREX_VERSION, "$LIBCOMPREX_VERSION",
	[libcomprex version.])

dnl ################################################################
dnl # libtool versioning
dnl ################################################################
dnl #
dnl # +1 :  0 : +1   == new interface that does not break old one.
dnl # +1 :  0 :  0   == removed an interface. Breaks old apps.
dnl #  ? : +1 :  ?   == internal changes that doesn't break anything.
dnl #
dnl # CURRENT : REVISION : AGE
dnl #
LT_CURRENT=3
LT_REVISION=0
LT_AGE=0

LT_RELEASE=$LIBCOMPREX_MAJOR_VERSION.$LIBCOMPREX_MINOR_VERSION.$LIBCOMPREX_MICRO_VERSION

AC_SUBST(LT_RELEASE)
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)

dnl ################################################################
dnl # Initialize automake
dnl ################################################################
VERSION=$LIBCOMPREX_VERSION
PACKAGE=libcomprex

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl ################################################################
dnl # Specify a header configuration file
dnl ################################################################
AM_CONFIG_HEADER(config.h)

AC_PATH_PROG(sedpath, sed)

dnl ################################################################
dnl # Setup gettext
dnl ################################################################
ALL_LINGUAS="it nl"
AM_GNU_GETTEXT
AM_GNU_GETTEXT_VERSION(0.10.40)

dnl Set PACKAGE_LOCALE_DIR in config.h.
if test "x${prefix}" = "xNONE"; then
    AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR,
	                   "${ac_default_prefix}/${DATADIRNAME}/locale",
	                   [locale directory, needed by gettext])
else
    AC_DEFINE_UNQUOTED(PACKAGE_LOCALE_DIR,
	                   "${prefix}/${DATADIRNAME}/locale",
	                   [locale directory, needed by gettext])
fi


dnl ################################################################
dnl # Check for some standard stuff.
dnl ################################################################
AC_PROG_CC
#AC_ARG_PROGRAM
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_PROG_LN_S
AC_PROG_INSTALL

AC_C_CONST
AC_TYPE_SIZE_T
AC_EXEEXT

AC_HEADER_STDC
AC_HEADER_DIRENT
AC_HEADER_STAT

AM_WITH_DMALLOC
AM_WITH_LEAKBUG

AC_CHECK_FUNCS(lchown atexit on_exit)
AC_CHECK_HEADERS(fcntl.h pwd.h string.h unistd.h sys/stat.h)

###########################################################################
# Check for modules
###########################################################################
AM_MODULE_CHECKS


dnl ################################################################
dnl # Setup libltdl
dnl ################################################################
modlibdir='${libdir}'/comprex
AC_SUBST(modlibdir)

AC_LIBLTDL_CONVENIENCE

if test "x$enable_dynamic_mods" != "xyes"; then
	INCLTDL=
	LIBLTDL=
fi

AC_SUBST(INCLTDL)
AC_SUBST(LIBLTDL)

AM_ENABLE_SHARED
AC_LIBTOOL_DLOPEN

AM_PROG_LIBTOOL

AC_CONFIG_SUBDIRS(libltdl)

if test x"$enable_shared" = xyes; then
	DLLDFLAGS=-export-dynamic
	AC_SUBST(DLLDFLAGS)
fi


dnl # Use wall if we have GCC
if test "x$GCC" = "xyes"; then
	CFLAGS="$CFLAGS -Wall"
fi

AC_SUBST(CFLAGS)

dnl ################################################################
dnl # Output the Makefiles
dnl ################################################################
AC_OUTPUT([
comprex-config
libcomprex.m4
libcomprex.pc
libcomprex.spec
Doxyfile
Makefile
debian/Makefile
debian/rules
docs/Makefile
docs/api/Makefile
docs/api/html/Makefile
docs/api/man/Makefile
intl/Makefile
libcomprex/Makefile
modules/Makefile
modules/archive/Makefile
modules/archive/ar/Makefile
modules/archive/bzip2/Makefile
modules/archive/cab/Makefile
modules/archive/cpio/Makefile
modules/archive/tar/Makefile
modules/archive/zip/Makefile
modules/archive/zlib/Makefile
modules/scheme/Makefile
modules/scheme/curl/Makefile
po/Makefile.in
tests/Makefile
])

AC_OUTPUT_COMMANDS([chmod +x comprex-config debian/rules])

echo
echo $PACKAGE v$VERSION
echo
echo "Building dynamic archive modules..: $enable_archive_mods"
echo "Building dynamic scheme modules...: $enable_scheme_mods"

if test "x$STATIC_ARCHIVE_MODS" != "x"; then
	echo "Archive modules to link statically: $STATIC_ARCHIVE_MODS"
fi

if test "x$STATIC_SCHEME_MODS" != "x"; then
	echo "Scheme modules to link statically.: $STATIC_SCHEME_MODS"
fi

if test "x$ac_curl_support" != "xyes"; then
	echo
	echo "Warning: You are compiling without libcurl support."
	echo "         This will prevent you from retrieving data"
	echo "         from any place other than your local filesystem."
	echo "         Please download curl from http://curl.haxx.se/"
	echo
fi

dnl See if the old modules are there.
if test -f "/usr/lib/comprex/archive/zlib.so" -o \
        -f "/usr/local/lib/comprex/scheme/curl.so"; then
	echo 
	echo "Warning: You have old archive and scheme modules installed."
	echo "         It is recommended that you delete all files in"
	echo "         /usr/lib/comprex/archive and /usr/lib/comprex/scheme, or"
	echo "         /usr/local/comprex/archive and /usr/local/lib/comprex/scheme,"
	echo "         depending on where they might be installed."
fi

echo
echo "Now type make to compile"
echo "Then su to root and type: make install"
echo