AC_INIT(nightfall, 1.62)
AC_CONFIG_SRCDIR(Light.c)
AM_INIT_AUTOMAKE(AC_PACKAGE_NAME, AC_PACKAGE_VERSION)

AC_ISC_POSIX
AM_PROG_CC_STDC
dnl AC_PROG_CC
AC_PROG_F77
AC_PROG_INSTALL

dnl Checks for programs.
AC_PROG_LN_S
AC_PROG_AWK
AC_PATH_PROG(MY_PERL, perl, no) 
if test x${MY_PERL} != xno ; then
	cat ${srcdir}/colormake.pl.in | sed s%FOOBAR%${MY_PERL}%g > colormake.pl
	chmod +x colormake.pl
else
	echo "No perl found"
fi


dnl i18n stuff
ALL_LINGUAS="de it"

AM_GNU_GETTEXT



dnl
dnl check for gnome
dnl
have_gnome="no"
GNOME_INSTALL=
GNOME_UNINSTALL=
AC_ARG_ENABLE(gnome, [  --disable-gnome      Disable GNOME support], 
	[
        if test "x${enable_gnome}" = "xno"; then
                :
        fi
	],
	[
		PKG_CHECK_MODULES(GNOME, libgnomeui-2.0 >= 2.0 gtk+-2.0 >= 2.6,
		[
			have_gnome="yes"
			AC_DEFINE([HAVE_GNOME], 1, [Define if you have gnome.])
			GNOME_INSTALL="install-nobinGNOME"
			GNOME_UNINSTALL="uninstall-nobinGNOME"
		],
		[
		      echo "*** Cannot find libgnomeui-2 on your system"
		      echo "*** (or gtk+-2 >= 2.6)"
		])
	]
)
AC_SUBST(GNOME_INSTALL)
AC_SUBST(GNOME_UNINSTALL)

dnl
dnl check for bells 
dnl
MY_FOLD=
MY_FORTUNE=
AC_CHECK_PROG(MY_FORTUNE,fortune,yes,no)
AC_CHECK_PROG(MY_FOLD,fold,yes,no)
if test ${MY_FOLD} = yes ; then
  if test $MY_FORTUNE = yes ; then  
    AC_DEFINE([HAVE_FORTUNE], 1, [Define if you want funny quotes.])
  fi
fi

dnl
dnl check for ps driver 
dnl
PS_DRIVER=
AC_CHECK_PROG(PS_DRIVER,a2ps,yes,no)
if test ${PS_DRIVER} = yes ; then
    AC_DEFINE([HAVE_A2PS], 1, [Define if you want printed output.])
fi

dnl
dnl profiling
dnl
AC_SUBST(PROFILE)
AC_SUBST(PLIBS)
AC_ARG_ENABLE(profiling, [  --enable-profiling      Enable profiling], PROFILE="-pg", PROFILE="")  


dnl
dnl Checks for header files.
dnl
AC_CHECK_HEADERS(unistd.h sys/timers.h)
dnl AC_HEADER_STDC what if not ???

dnl
dnl Checks for typedefs, structures, and compiler characteristics.
dnl
AC_C_CONST
AC_STRUCT_TM

dnl
dnl Checks for library functions.
dnl
AC_CHECK_FUNCS(mkfifo)
AC_CHECK_FUNCS(putenv)


dnl
dnl Only use -Wall and some minor optimizations if we have gcc
dnl
if test "x$GCC" = "xyes"; then
  if test ! -z "`echo " $CFLAGS" | grep ' \-g ' 2> /dev/null`" ; then
    CFLAGS=`echo " $CFLAGS" | sed 's% \-g %%' `
  fi
  if test ! -z "`echo "$CFLAGS" | grep "\-O2" 2> /dev/null`" ; then
    CFLAGS=`echo $CFLAGS | sed 's%\-O2%%' `
  fi
  if test -z "`echo "$CFLAGS" | grep "\-Wall" 2> /dev/null`" ; then
    CFLAGS="$CFLAGS -Wall"
  fi
  if test -z "`echo "$CFLAGS" | grep "\-O3" 2> /dev/null`" ; then
    CFLAGS="$CFLAGS -O3"
  fi
dnl  if test -z "`echo "$CFLAGS" | grep "\-funroll\-loops" 2> /dev/null`" ; then
dnl    CFLAGS="$CFLAGS -funroll-loops"
dnl  fi
  if test -z "`echo "$CFLAGS" | grep "\-fforce\-addr" 2> /dev/null`" ; then
    CFLAGS="$CFLAGS -fforce-addr"
  fi
fi

dnl
dnl Test for Gtk+
dnl
if test x"$have_gnome" = "xyes"
then
  GTK_LIBS=${GNOME_LIBS}
  GTK_CFLAGS=${GNOME_CFLAGS}
  my_have_gtk2="yes"
else
  GTK_LIBS=
  GTK_CFLAGS=
  AC_ARG_ENABLE(gtk2,[  --disable-gtk2      Do not try to use GTK 2],
            gtk_try_v2="$enableval", gtk_try_v2="yes")

  my_have_gtk2="no"

  if test "x${gtk_try_v2}" = xyes
  then
    PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.6 glib-2.0 >= 2.0, 
     [my_have_gtk2="yes"],[
     echo "*** Cannot find gtk+-2 >= 2.6 on your system"
     echo "*** Continue searching for gtk+ >= 1.1.0"
     ])
  fi
fi

dnl GTK_DISABLE_COMPAT_H
dnl GDK_DISABLE_DEPRECATED

if test "x${GTK_LIBS}" = x
then
AM_PATH_GTK(1.2.0,
  	    [
	    #LIBS="$LIBS $GTK_LIBS"
            #CFLAGS="$CFLAGS $GTK_CFLAGS"
            AC_DEFINE([_WITH_GTK], 1, [Define if you have GTK.])
	    AC_DEFINE([GTK_DISABLE_COMPAT_H], 1, [Undefine compat header.])
	    my_gtk_test="yes"
	    AC_PATH_X
	    AC_PATH_XTRA
	    ],
            AC_MSG_WARN(Cannot find GTK: Is gtk-config in path?))
else
	    my_gtk_test="yes"
            AC_DEFINE([_WITH_GTK], 1, [Define if you have GTK.])
	    AC_DEFINE([USING_GTK2], 1, [Define if you have GTK2.])

	    AC_DEFINE([GTK_DISABLE_COMPAT_H], 1, [Undefine compat header.])
	    AC_DEFINE([GDK_DISABLE_DEPRECATED], 1, [No deprecated functions.])

	    AC_PATH_X
	    AC_PATH_XTRA
	    AC_SUBST(X_CFLAGS)
	    AC_SUBST(X_LIBS)
	    AC_SUBST(X_EXTRA_LIBS)
	    AC_SUBST(X_PRE_LIBS)
	    #LIBS="$LIBS ${X_LIBS} ${GTK_LIBS}"
	    #CFLAGS="$CFLAGS ${X_CFLAGS} ${GTK_CFLAGS}"
fi


my_usedisk=yes
AC_ARG_ENABLE(disk, [  --disable-disk		       Experimental and unfinished], 
	[
        if test "x${enable_disk}" = "xno"; then
	   my_usedisk=no
        fi
	]
)
if test "x${my_usedisk}" = "xyes"; then
   AC_DEFINE([HAVE_DISK], 1, [Define if needed.])
fi

AC_ARG_ENABLE(high-precision, [  --enable-high-precision      Reeaaal sloooow], 
	[
        if test "x${enable_high_precision}" = "xyes"; then
                AC_DEFINE([HIGH_PRECISION], 1, [Define if needed.])
        fi
	]
)

dnl
dnl Test for GL/MesaGL -- taken from gtkglarea
dnl
AC_ARG_ENABLE(opengl, [  --disable-opengl      Disable OpenGL support], 
	[
        if test "x${enable_opengl}" = "xno"; then
                my_opengl="no"
        fi
	]
)

AC_ARG_WITH(gl-prefix,    [  --with-gl-prefix=PFX   Prefix where OpenGL or Mesa is installed],
 gl_prefix="$withval",
 gl_prefix="")

AC_ARG_WITH(gtkgl-prefix, [  --with-gtkgl-prefix=PFX Prefix where GtkGLArea is installed],
 gtkgl_prefix="$withval",
 gtkgl_prefix="")

AC_ARG_WITH(lib-GL,     [  --with-lib-GL           use '-lGL'])
AC_ARG_WITH(lib-MesaGL, [  --with-lib-MesaGL       use '-lMesaGL'])

GL_LIBS=""

## tests for OpenGL
if test x$gl_prefix != x ; then
 GL_CFLAGS="-I$gl_prefix/include"
 GL_LDOPTS="-L$gl_prefix/lib"
else
 GL_CFLAGS=""
 GL_LDOPTS=""
fi

saved_LIBS="$LIBS"
saved_CFLAGS="$CFLAGS"

AC_MSG_CHECKING([OpenGL])
LIBS="$saved_LIBS $GTK_LIBS $GL_LDOPTS -lGLU -lGL"
AC_TRY_LINK( ,[ char glBegin(); glBegin(); ], have_GL=yes, have_GL=no)
AC_MSG_RESULT($have_GL)

AC_MSG_CHECKING([Mesa])
LIBS="$saved_LIBS $GTK_LIBS $GL_LDOPTS -lMesaGLU -lMesaGL"
AC_TRY_LINK( ,[ char glBegin(); glBegin(); ], have_MesaGL=yes, have_MesaGL=no)
AC_MSG_RESULT($have_MesaGL)

if test "x$have_MesaGL" = "xno"; then
 AC_MSG_CHECKING([Mesa with pthreads])
 LIBS="$saved_LIBS $GTK_LIBS $GL_LDOPTS -lMesaGLU -lMesaGL -lpthread"
 AC_TRY_LINK( ,[ char glBegin(); glBegin(); ], have_MesaGL_pthread=yes, have_MesaGL_pthread=no)
 AC_MSG_RESULT($have_MesaGL_pthread)
fi

LIBS="$saved_LIBS"

if test "x$with_lib_MesaGL" = "xyes"; then

 if test "x$have_MesaGL" = "xyes"; then
  GL_LIBS="$GL_LDOPTS -lglut -lMesaGLU -lMesaGL -lXmu"
  echo " -- using MesaGL"
 elif test "x$have_MesaGL_pthread" = "xyes"; then
  GL_LIBS="$GL_LDOPTS -lglut -lMesaGLU -lMesaGL -lXmu -lpthread"
  echo " -- using MesaGL with pthreads"
 else
  AC_MSG_ERROR(MesaGL not available)
 fi

elif test "x$with_lib_GL" = "xyes"; then

 if test "x$have_GL" = "xyes"; then
  GL_LIBS="$GL_LDOPTS -lglut -lGLU -lGL"
  echo " -- using OpenGL"
 else
  AC_MSG_ERROR(OpenGL not available)
 fi

else

 if test "x$have_GL" = "xyes"; then
  GL_LIBS="$GL_LDOPTS -lglut -lGLU -lGL"
  echo " -- using OpenGL"
 elif test "x$have_MesaGL" = "xyes"; then
  GL_LIBS="$GL_LDOPTS -lglut -lMesaGLU -lMesaGL -lXmu"
  echo " -- using MesaGL"
 elif test "x$have_MesaGL_pthread" = "xyes"; then
  GL_LIBS="$GL_LDOPTS -lglut -lMesaGLU -lMesaGL -lpthread -lXmu"
  echo " -- using MesaGL with pthreads"
 fi

fi

dnl AC_SUBST(GL_CFLAGS)
dnl AC_SUBST(GL_LIBS)

## tests for GtkGLArea

have_gtkgl="no"

if test x"$my_have_gtk2" = "xyes"
then
    PKG_CHECK_MODULES(GTKGL, gtkgl-2.0 >= 1.0, 
		      [
		      have_gtkgl="yes"
		      ],
		      [
		      have_gtkgl="no"
		      echo "*** Cannot find gtkgl-2 on your system"
		      ])
else

if test x"$have_gtkgl" = "xno"
then
    PKG_CHECK_MODULES(GTKGL, gtkgl >= 1.2,  
		      [
		      have_gtkgl="yes"
		      ],
		      [
		      have_gtkgl="no"
		      echo "*** Cannot find gtkgl with pkg-config"
		      echo "*** Continue searching for gtkgl >= 1.2"
		      ])
fi

if test x"$have_gtkgl" = "xno"
then
    if test x$gtkgl_prefix != x; then
      GTKGL_CFLAGS="-I$gtkgl_prefix/include"
      GTKGL_LIBS="-L$gtkgl_prefix/lib -lgtkgl"
    else
      GTKGL_CFLAGS=""
      GTKGL_LIBS="-lgtkgl"
    fi

    AC_MSG_CHECKING([GtkGLArea])
    LIBS="$saved_LIBS $X_LIBS $X_EXTRA_LIBS $GTKGL_LIBS $GTK_LIBS $GL_LDOPTS $GL_LIBS"
    AC_TRY_LINK([],[ char gtk_gl_area_new(); gtk_gl_area_new(); ], 
		 [have_gtkgl=yes], [have_gtkgl=no])
    AC_MSG_RESULT($have_gtkgl)
fi
fi

if test "x${my_opengl}" != "xno" -a "x${have_gtkgl}" = xyes; then

  LIBS="$saved_LIBS"
  CFLAGS="$saved_CFLAGS"
  GTKGL_CFLAGS="$X_CFLAGS $GTKGL_CFLAGS $GTK_CFLAGS $GL_CFLAGS"
  GTKGL_LIBS="$X_LIBS $X_EXTRA_LIBS $GTKGL_LIBS $GTK_LIBS $GL_LDOPTS $GL_LIBS"

else

 LIBS="$saved_LIBS $X_LIBS $X_EXTRA_LIBS $GTK_LIBS"
 CFLAGS="$saved_CFLAGS $X_CFLAGS $GTK_CFLAGS"
 GTKGL_LIBS=""
 GTKGL_CFLAGS=""

fi


dnl AC_SUBST(GTKGL_CFLAGS)
dnl AC_SUBST(GTKGL_LIBS)

dnl my_gtkgl="no"
dnl saved_CPPFLAGS="$CPPFLAGS"
dnl CPPFLAGS="$CPPFLAGS $GTK_CFLAGS"
dnl AC_CHECK_HEADER(gtkgl/gtkglarea.h,[my_gtkgl="yes"])
dnl CPPFLAGS="$saved_CPPFLAGS"

my_jpeg="no"
AC_CHECK_HEADER(jpeglib.h,[my_jpeg="yes"])

if test "x${my_opengl}" != "xno"; then
  if test x$have_gtkgl = xyes; then
    if test "x$my_jpeg" != "xno"; then
      if test "x$my_gtkgl" != "xno"; then
	CFLAGS="$CFLAGS $GTKGL_CFLAGS"
	LIBS="$LIBS $GTKGL_LIBS -ljpeg"
	# LIBS="$LIBS $GL_LIBS -lgtkgl -ljpeg"
	AC_DEFINE([_WITH_OPENGL], 1, [Define if you have OpenGL.])
      fi
    else
	echo " -- OpenGL disabled (jpeglib not found)"
    fi
  else
	echo " -- OpenGL disabled (gtkgl not found)"
  fi
else
   echo " -- OpenGL disabled"
fi

my_mpi=no
dnl AC_ARG_ENABLE(mpi-fine, 
dnl	[  --enable-mpi-fine		Enable use of MPI for parallelization],
dnl 	[
dnl         if test "x${enable_mpi}" = "xyes"; then
dnl                 AC_DEFINE([_WITH_MPI], 1, [Define for MPI.])
dnl 		my_mpi=fine
dnl         fi
dnl 	])

AC_ARG_ENABLE(mpi, 
        [  --enable-mpi		Enable use of MPI for parallelization],
	[
        if test "x${enable_mpi}" = "xyes"; then
		if test x"${my_mpi}" != xno; then
			AC_MSG_ERROR(mpi already enabled)
		else
                	AC_DEFINE([_WITH_MPI_COARSE], 1, [Define for MPI.])
		fi
        fi
	])


dnl Test for PGPLOT AFTER Gtk+ because gtk-config adds libraries
dnl and other stuff to compile a test code
dnl actually no test program yet 
AC_MSG_CHECKING(how to plot output)
AC_MSG_RESULT(let's see)
graphtype=no


AC_ARG_WITH(gnuplot, 
        [  --with-gnuplot	Force using gnuplot, skip test],
	[  AC_DEFINE([_WITH_PGPLOT], 1, [Define for plots.])
           AC_DEFINE([_WITH_GNUPLOT], 1, [Define for plots with gnuplot.])
	   F77="$CC" 
	   fortran="no"
           graphtype="gnuplot"
	   AC_MSG_WARN(build with gnuplot support enforced ... no testing done)])

dnl
dnl check for fortran compiler, set cflags if native compiler
dnl PGPLOT cflags from PGPLOT system-specific config files
dnl thanks to Hans Schwengeler <schweng@astro.unibas.ch>
dnl for testing on Dec OSF/1
dnl

if test x$F77 = x ; then
  F77="$CC"
  fortran="no"
else
  if test "x$GCC" = "x"; then
    AC_CANONICAL_HOST 
    case $host_os in
      ultrix*)
	  CC="$CC -Dmain=MAIN_"
	  ;;
      osf*)
	  CC="$CC -Dmain=MAIN__"
	  ;;
      sunos*)
	  CC="$CC -Dmain=MAIN_"
	  ;;
    esac
  fi
fi

if test x$fortran != xno ; then
  AC_MSG_CHECKING(for PGPLOT)
  AC_ARG_WITH(pgplot-include,
        [  --with-pgplot-include=PFX  	Prefix for PGPLOT include files],
	pgplot_include="$withval",
	[ pgplot_include="/usr/include"
	  if test -f ${pgplot_include}/cpgplot.h; then
		:
	  else
		pgplot_include="/usr/local/include"
	  fi
	  if test -f ${pgplot_include}/cpgplot.h; then
		:
	  else
		pgplot_include="/usr/local/pgplot"
	  fi]
	)
  AC_ARG_WITH(pgplot-lib, 
        [  --with-pgplot-lib=PFX	Prefix for PGPLOT library files], 
	pgplot_lib="$withval",
	[ pgplot_lib="/usr/lib"
	  if test -f ${pgplot_lib}/libcpgplot.a; then
		:
	  else
		pgplot_lib="/usr/local/lib"
	  fi
  	  if test -f ${pgplot_lib}/libcpgplot.a; then
		:
	  else
		pgplot_lib="/usr/local/pgplot"
  	  fi]
	)
  if test x$pgplot_include != x; then
	  if test -f ${pgplot_include}/cpgplot.h ; then
		my_back_flags="$CFLAGS"
		my_back_libs="$LIBS"
		PGPLOT_INCLUDE="-I$pgplot_include"
		PGPLOT_LIB="-L$pgplot_lib"
        	PGPLOT_LIB="$PGPLOT_LIB -lcpgplot -lpgplot"
		PGPLOT_LIB="$PGPLOT_LIB -L/usr/X11R6/lib -lX11"
		CFLAGS="$PGPLOT_INCLUDE $CFLAGS"
		LIBS="$PGPLOT_LIB $LIBS"
		if test -z "`echo "$FFLAGS" | grep "\-O2" 2>/dev/null`"; then
                        CFLAGS=`echo $CFLAGS | sed 's%\-O2%%' `
                fi
		AC_LANG_C_AND_F77
		err1msg=" tried compile with ${CC-cc} -c $CFLAGS $CPPFLAGS"
		err2msg=" tried link    with ${F77-f77} -o conftest${ac_exeext} $CFLAGS $FFLAGS $LDFLAGS conftest.$ac_ext $LIBS"
		AC_TRY_LINK([#include "cpgplot.h"],
		[cpgopen("/NULL"); /* open NULL device */ 
                cpgscf(2);         /* set colour       */
                cpgend();          /* end plot         */],
                [
		AC_MSG_RESULT(compiles and links)
                AC_DEFINE([_WITH_PGPLOT], 1, [Define for plots.])
                graphtype="pgplot"
		echo "  -- using files in ${pgplot_include}, ${pgplot_lib}"
		],
                [
		AC_MSG_RESULT([does not work properly])
		echo "$err1msg"
		echo "$err2msg"
                F77="$CC"
		CFLAGS="$my_back_flags"
		LIBS="$my_back_libs"
		])
	else
		AC_MSG_RESULT(no)
		FF="$CC"
	fi
  fi
else
  if test x$graphtype = xno; then
    AC_MSG_WARN(skip search for PGPLOT ... no Fortran compiler for linking)
  fi
fi



# if not PGPLOT, test for GNUPLOT
if test x$graphtype = xno; then
    F77="$CC"
    AC_MSG_CHECKING(for GNUPLOT)
    echo "set bkbkhkjhk" > conftest_test ;
    gnuplot conftest_test 2> conftest_res ;
    GPL_TEST=`grep "multiplot" conftest_res` ;
#   if "multiplot" is in the list of options
    if test "${GPL_TEST}blah" != blah ; then
      AC_DEFINE([_WITH_PGPLOT], 1, [Define for plots.])
      AC_DEFINE([_WITH_GNUPLOT], 1, [Define for plots with gnuplot.]) 
      AC_MSG_RESULT(yes)
    else
      AC_MSG_RESULT(no)
      AC_MSG_WARN(GNUPLOT is not in path or version too old)
      AC_MSG_WARN(no plotting program found)
      AC_MSG_WARN(no graphic output will be possible)
    fi
    rm -rf conftest*
fi

mydataroot="${datadir}/${PACKAGE}"
AC_SUBST(mydataroot)

AC_ARG_WITH(data-prefix,
        [  --with-data-prefix=PFX	Set install dir for data files],
	mydatadir="$withval",
	mydatadir="${mydataroot}/data")
AC_SUBST(mydatadir)

AC_ARG_WITH(cfg-prefix,
        [  --with-cfg-prefix=PFX  	Set install dir for cfg files],
	mycfgdir="$withval",
	mycfgdir="${mydataroot}/cfg")
AC_SUBST(mycfgdir)

AC_ARG_WITH(doc-prefix,
        [  --with-doc-prefix=PFX  	Set install dir for doc files],
	mydocdir="$withval",
	mydocdir="${mydataroot}/doc")
AC_SUBST(mydocdir)

AC_ARG_WITH(gnomedoc-prefix,
        [  --with-gnomedoc-prefix=PFX  	Set install dir for gnome help files],
	mygdocdir="$withval",
	mygdocdir="${mydataroot}")
AC_SUBST(mygdocdir)

AC_ARG_WITH(locale-prefix,
        [  --with-locale-prefix=PFX	Set install dir for locale files],
	mylocaledir="$withval",
	mylocaledir="${datadir}/locale")
AC_SUBST(mylocaledir)

AC_ARG_WITH(pixmap-prefix,
        [  --with-pixmap-prefix=PFX	Set install dir for pixmap files],
	mypixmapdir="$withval",
	mypixmapdir="${mydataroot}/pixmaps")
AC_SUBST(mypixmapdir)

AC_ARG_WITH(manual-prefix,
        [  --with-manual-prefix=PFX	Set install dir for user manual],
	mymanualdir="$withval",
	mymanualdir="${mydataroot}/doc")
AC_SUBST(mymanualdir)

my_save_prefix="${prefix}"
if test "X$prefix" = "XNONE"; then
    prefix="$ac_default_prefix"
else
    prefix="$prefix"
fi
PREFIX=`eval echo ${prefix}` ;          PREFIX=`eval echo ${PREFIX}`
AC_DEFINE_UNQUOTED([PREFIX], ["$PREFIX"], [Installation prefix])
SYSCONFDIR=`eval echo ${sysconfdir}` ;  SYSCONFDIR=`eval echo ${SYSCONFDIR}`
AC_DEFINE_UNQUOTED([SYSCONFDIR], ["$SYSCONFDIR"], [Installation sysconfdir])
DATADIR=`eval echo ${mydataroot}` ;     DATADIR=`eval echo ${DATADIR}`
AC_DEFINE_UNQUOTED([DATADIR], ["$DATADIR"], [Installation datadir])
LIBDIR=`eval echo ${libdir}` ;          LIBDIR=`eval echo ${LIBDIR}`
AC_DEFINE_UNQUOTED([LIBDIR], ["$LIBDIR"], [Installation libdir])
GDOCDIR=`eval echo ${mygdocdir}` ;          GDOCDIR=`eval echo ${GDOCDIR}`
AC_DEFINE_UNQUOTED([GDOCDIR], ["$GDOCDIR"], [Installation gnome_param_app_datadir])
prefix="${my_save_prefix}"

AC_CONFIG_HEADER(config.h)

AC_OUTPUT([ 
Makefile
intl/Makefile 
po/Makefile.in
nightfall.spec
])

echo
echo configure complete, now type \'make\', or \'./cmake\' for colourized output
echo 


A=`eval echo ${bindir}` ;      A=`eval echo ${A}`
B=`eval echo ${mymanualdir}` ; B=`eval echo ${B}`
C=`eval echo ${mandir}` ;      C=`eval echo ${C}`
D=`eval echo ${mylocaledir}` ;  D=`eval echo ${D}`
E=`eval echo ${mydocdir}` ;   E=`eval echo ${E}`
F=`eval echo ${mydatadir}` ;  F=`eval echo ${F}`
G=`eval echo ${mypixmapdir}` ;  G=`eval echo ${G}`
H=`eval echo ${mycfgdir}` ;  H=`eval echo ${H}`


echo "
Configuration:

  Source code location:       ${srcdir}
  Compiler:                   ${CC}
  Compiler flags:             ${CFLAGS}
  Executable:                 ${A}
  User Manual:                ${B}
  Manpage:                    ${C}
  Localization:               ${D}
  Help files:                 ${E}
  Data files:                 ${F}
  Pixmaps:                    ${G}
  Star configurations:        ${H}"

if test -n "$xv_bindir"; then
echo "  XView version install path: ${xv_bindir}"
fi
echo ""