dnl Process this file with autoconf to produce a configure script.

AC_INIT(ghostess, 20061127, musound-at-jps-dot-net)

AC_CONFIG_SRCDIR(src/ghostess.c)
AM_INIT_AUTOMAKE
AM_CONFIG_HEADER(config.h)

AC_ISC_POSIX
AC_PROG_CC
AM_PROG_CC_STDC
AC_HEADER_STDC

dnl AC_ENABLE_STATIC(no)
dnl AC_ENABLE_SHARED(yes)
AC_LIBTOOL_DLOPEN
AC_PROG_LIBTOOL

AC_C_BIGENDIAN

dnl Check for GTK+
AC_ARG_WITH(gtk2, AC_HELP_STRING([--with-gtk2], [use GTK+ 2.0 default=yes]),
            [ if test $withval = "yes"; then try_gtk2=yes ;
              else try_gtk2=no ; fi ], try_gtk2=yes)
with_gtk=no
dnl First look for GTK+ 2.x, unless '--without-gtk2' was specified.
if test "x${try_gtk2}" = 'xyes'; then
    AM_PATH_GTK_2_0(2.0.0, with_gtk='yes (version 2.0)', with_gtk=no)
fi
dnl  No GTK+ 2.x found, look for GTK+ 1.2 instead
if test "x${with_gtk}" = 'xno'; then
    AM_PATH_GTK(1.2.0, with_gtk='yes (version 1.2)', AC_MSG_ERROR(Cannot find GTK+!))
fi
echo "GTK support: $with_gtk"

dnl OS specific checks
case "${host_os}" in
darwin*)
  darwin=yes
  AC_DEFINE(MIDI_COREMIDI, 1, [Define for CoreMIDI support on Mac OS X])
  PKG_CHECK_MODULES(ALSA, libdssialsacompat)
  ;;
*)
  darwin=no
  PKG_CHECK_MODULES(ALSA, alsa >= 0.9.0)
  ;;
esac
AM_CONDITIONAL(DARWIN, test x$darwin = xyes)

dnl Require DSSI and liblo
PKG_CHECK_MODULES(MODULE, dssi >= 0.9 liblo >= 0.12)

dnl Check for JACK: need jack 0.99.0+ for jack_last_frame_time()
PKG_CHECK_MODULES(JACK, jack >= 0.99.0)
AC_SUBST(JACK_CFLAGS)
AC_SUBST(JACK_LIBS)

dnl Check for JACK MIDI support
AC_ARG_WITH(jackmidi,AC_HELP_STRING([--with-jackmidi], [default=yes]),
	[ if test $withval = "yes";then with_jack_midi=yes;
		else with_jack_midi=no; fi ])
if test x${with_jack_midi} = 'xyes'; then
AC_CHECK_LIB(jack, jack_midi_get_event_count,
             [with_jack_midi=yes
              AC_DEFINE(MIDI_JACK, 1, [Define for JACK MIDI support])],
             with_jack_midi=no, $JACK_LIBS)
else if test x${darwin} = 'xno'; then
	AC_DEFINE(MIDI_ALSA, 1, [Define for ALSA MIDI support on Linux])
fi fi
AM_CONDITIONAL(MIDI_JACK, test x$with_jack_midi = xyes)

dnl Use lotsa flags if we have gcc.
CFLAGS="$CFLAGS $ALSA_CFLAGS $MODULE_CFLAGS"
LDFLAGS="$LDFLAGS $ALSA_LIBS $MODULE_LIBS"
changequote(,)dnl
if test "x$GCC" = "xyes"; then
  case " $CFLAGS " in
  *[\ \	]-Wall[\ \	]*) ;;
  *) CFLAGS="$CFLAGS -Wall" ;;
  esac
  case " $CFLAGS " in
  *[\ \	]-O[1-9][\ \	]*) ;;
  *) CFLAGS="$CFLAGS -O2 -s -fomit-frame-pointer -funroll-all-loops -finline-functions -ffast-math -Winline" ;;
  esac
  # add '-finline-limit=...' only for GCC 3.x:
  #case `$CC -dumpversion 2>/dev/null` in
  #3.*) CFLAGS="$CFLAGS -finline-limit=5000" ;;
  #esac
fi
changequote([,])dnl

AC_OUTPUT([
Makefile
src/Makefile
])