dnl Process this file with autoconf to produce a configure script.
AC_INIT(xhippo.c)
AM_CONFIG_HEADER(config.h)

PACKAGE=xhippo
VERSION=3.3
ALL_LINGUAS="de"
AC_SUBST(PACKAGE)
AC_SUBST(VERSION)

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
AM_MAINTAINER_MODE

dnl Checks for programs.
AC_PROG_CC

AM_GNU_GETTEXT

AC_ARG_WITH(gnome,
[  --with-gnome            compile with GNOME support [default=no]], WANTEDGNOME=yes, WANTEDGNOME=no)
AC_ARG_WITH(gtk2,
[  --with-gtk2             compile with GTK2 support [default=no]], WANTEDGTK2=yes, WANTEDGTK2=no)
AC_ARG_WITH(prefs-dialog,
[  --with-prefs-dialog     compile in support for experimental prefs dialog [default=no]], AC_DEFINE(USEPREFS, 1, [Enable preferences dialog]))

dnl Checks for header files.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(fcntl.h sys/time.h unistd.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_PID_T

dnl Checks for library functions.
AC_CHECK_FUNCS(strdup, , AC_MSG_ERROR(No strdup found. Unusual.))
AC_CHECK_FUNCS(fork, , AC_MSG_ERROR(No fork found.))
AC_CHECK_FUNCS(getopt_long, , AC_MSG_WARN(getopt_long not found. Long options will not work.) ; AC_DEFINE(NOGETOPTLONG, 1, [No getopt_long]) )
AC_CHECK_FUNCS(strcasecmp, , AC_DEFINE(NOSTRCASECMP, 1, [No strcasecmp]))
AC_CHECK_FUNCS(getopt, , AC_MSG_ERROR(Ack! You don't even have getopt!))
AC_CHECK_FUNCS(snprintf, , AC_MSG_WARN(snprintf not found. Range checks will be disabled.))
AC_CHECK_FUNCS(nftw, , AC_MSG_WARN(nftw not found. Add Directory will be disabled.))
if test "x$WANTEDGTK2" = xyes ; then
	PKG_CHECK_MODULES(GLIB2, glib-2.0 >= 2.0.0)
	PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.0.0)
	AC_DEFINE(USEGTK2, 1, [Use GTK2 instead of GTK1])
else
	GTK2_LIBS=""
	GTK2_CFLAGS=""
	AC_SUBST(GTK2_LIBS)
	AC_SUBST(GTK2_CFLAGS)
	AM_PATH_GTK(1.2.0,,AC_MSG_ERROR(No sufficiently-recent GTK found; we need at least 1.2.0. Set the path right or install it.))
	AC_CHECK_PROG(foundgnome, gnome-config, yes, no)
fi

ID3LIBS=""
ZLIB=""
AC_CHECK_LIB(id3, ID3Tag_New, ID3LIBS="-lid3"; ZLIB="-lz"; AC_DEFINE(HAVE_LIBID3, 1, [Have libid3]), , -lz)
AC_CHECK_LIB(id3tag, id3_file_tag, ID3LIBS="$ID3LIBS -lid3tag"; ZLIB="-lz"; AC_DEFINE(HAVE_LIBID3TAG, 1, [Have libid3tag]), , -lz)
ID3LIBS="$ID3LIBS $ZLIB"
AC_SUBST(ID3LIBS)

I18N_CFLAGS='-I$(top_srcdir)/intl'
I18N_LIBS=$INTLLIBS
AC_SUBST(I18N_CFLAGS)
AC_SUBST(I18N_LIBS)

dnl This is *not* the right way to do this, but GNOME's native
dnl autoconf support is extremely baroque.

if test "x$WANTEDGTK2" = "xyes"; then
	UILIBS=""
	UIFLAGS=""
	echo "GTK2 used."
else
	UILIBS="$GTK_LIBS"
	UIFLAGS="$GTK_CFLAGS"
	if test "x$foundgnome" = "xyes"; then
		if test "x$WANTEDGNOME" = "xyes"; then
			echo "GNOME found and used."
			AC_DEFINE(USEGNOME, 1, [Use GNOME])
			UILIBS=`gnome-config --libs gnomeui`
			UIFLAGS=`gnome-config --cflags gnomeui`
		else
			echo "GNOME found but not used."
		fi
	else
		echo "GNOME not used."
	fi
fi
AC_SUBST(UILIBS)
AC_SUBST(UIFLAGS)

AC_OUTPUT(Makefile intl/Makefile po/Makefile.in m4/Makefile )