AC_INIT(OnTV, 2.4.0, ontv)
AC_CONFIG_HEADERS(config.h)
AC_CONFIG_MACRO_DIR([m4])

AM_INIT_AUTOMAKE([foreign])
AM_MAINTAINER_MODE
AM_PROG_LIBTOOL
AC_SUBST(ACLOCAL_AMFLAGS, "$ACLOCAL_FLAGS -I m4")
AC_PROG_CC

dnl ==========
dnl pkg-config
dnl ==========

AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
if test "x$HAVE_PKGCONFIG" = "xno"; then
    AC_MSG_ERROR(You need to have pkgconfig installed!)
fi

dnl ==================
dnl Translation & I18N
dnl ==================

ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS"`"
AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
GETTEXT_PACKAGE=ontv
AC_PROG_INTLTOOL([0.33])
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [The gettext package])
AM_GLIB_GNU_GETTEXT

dnl =====
dnl GConf
dnl =====

AC_PATH_PROG(GCONFTOOL, gconftool-2)
AM_GCONF_SOURCE_2

dnl ======
dnl Python
dnl ======

AM_PATH_PYTHON(2.4)
AM_CHECK_PYTHON_HEADERS(,[AC_MSG_ERROR(could not find Python headers)])

dnl ============
dnl Requirements
dnl ============

PKG_CHECK_MODULES(ONTV,
	gtk+-2.0 >= 2.10.0
	pygtk-2.0 >= 2.10.0
	pygobject-2.0 >= 2.12.0
	gnome-python-2.0 >= 2.16.0
	gnome-python-extras-2.0 >= 2.14.2
	notify-python >= 0.1.1)

AC_MSG_CHECKING([for cElementTree module])
if AC_RUN_LOG([$PYTHON -c '
try:
    import cElementTree
except ImportError, e:
    if str(e).find("cElementTree") >= 0:
          raise
except:
    pass
']); then
  AC_MSG_RESULT([yes])
else
  AC_MSG_RESULT([no])
  AC_MSG_ERROR([cElementTree Python module required to build ontv])
fi

AC_PATH_PROG(PYGTK_CODEGEN, pygtk-codegen-2.0, no)
if test "x$PYGTK_CODEGEN" = xno; then
  AC_MSG_ERROR(could not find pygtk-codegen-2.0 script)
fi

AC_MSG_CHECKING(for pygtk defs)
PYGTK_DEFSDIR=`$PKG_CONFIG --variable=defsdir pygtk-2.0`
AC_SUBST(PYGTK_DEFSDIR)
AC_MSG_RESULT($PYGTK_DEFSDIR)

AC_OUTPUT([
Makefile
data/Makefile
data/images/Makefile
ontv/__init__.py
ontv/Makefile
ontv/keybinder/Makefile
scripts/Makefile
po/Makefile.in
])