# == Initialization ==
AC_INIT([Timer Applet], [1.3.1], [crispyleaves@gmail.com], [timer-applet])

AC_CONFIG_SRCDIR([src/main.c])
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE
AM_MAINTAINER_MODE

# == Basic Compiler Settings ==
AC_PROG_CC
AC_HEADER_STDC
AC_PROG_RANLIB

# == Check for ScrollKeeper ==
AC_PATH_PROG(SCROLLKEEPER_CONFIG, scrollkeeper-config, [no])
if test x$SCROLLKEEPER_CONFIG = xno; then
	AC_MSG_ERROR([Couldn't find scrollkeeper-config in your PATH. Please install ScrollKeeper.])
fi

# == GConf ==
AC_PATH_PROG(GCONFTOOL, gconftool-2, [no])
if test x$GCONFTOOL = xno; then
  AC_MSG_ERROR([Couldn't find gconftool-2 in your PATH. Please install GConf.])
fi

AM_GCONF_SOURCE_2

# == Localization ==
GETTEXT_PACKAGE=timer-applet
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Gettext Package])
AC_SUBST(GETTEXT_PACKAGE)
ALL_LINGUAS="de eo es eu fi fr it ko pl sv tr"
AM_GLIB_GNU_GETTEXT
AC_PROG_INTLTOOL

# == Required Modules ==
GNOME_MODULES="gtk+-2.0 >= 2.6.0 gnome-vfs-2.0 >= 2.0.0 libgnomeui-2.0 >= 2.0.0 libpanelapplet-2.0 >= 2.0.0"
PKG_CHECK_MODULES([GNOME], $GNOME_MODULES)

# == libnotify ==
PKG_CHECK_MODULES([LIBNOTIFY], [libnotify >= 0.3.0], [enable_notify=yes], [enable_notify=no])
if test "x$enable_notify" = "xyes"; then
   AC_DEFINE([HAVE_LIBNOTIFY], [1], [Enable notifications with libnotify])
else
   AC_MSG_WARN([*** libnotify was not found. Notifications disabled. ***])
fi


# == Export compiler/linker options ==
AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)

# == Generate files ==
AC_CONFIG_FILES([
Makefile
help/Makefile
help/C/Makefile
help/fr/Makefile
src/Makefile
src/gloo/Makefile
src/gloo/tests/Makefile
pixmaps/Makefile
po/Makefile.in
])
AC_OUTPUT