dnl
AC_PREREQ(2.13)

AC_INIT(src/datadesigner.cc)

GLIB_AC_DIVERT_BEFORE_HELP([
DD_MAJOR_VERSION=0
DD_MINOR_VERSION=5
dnl DD_MICRO_VERSION=1
dnl DD_SNAPSHOT=pre1
if test "x$DD_SNAPSHOT" = "x"; then
    if test "x$DD_MICRO_VERSION" = "x"; then
	DD_VERSION=$DD_MAJOR_VERSION.$DD_MINOR_VERSION
    else
	DD_VERSION=$DD_MAJOR_VERSION.$DD_MINOR_VERSION.$DD_MICRO_VERSION
    fi
else
    DD_VERSION=$DD_MAJOR_VERSION.$DD_MINOR_VERSION.$DD_SNAPSHOT
fi
])

VERSION=$DD_VERSION
PACKAGE=datadesigner

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
AM_CONFIG_HEADER(config.h)

AC_CANONICAL_HOST
AC_PROG_CC
AC_PROG_CXX
COMPILE_WARNINGS
CXX_WARNINGS
AM_PROG_LIBTOOL
AC_PROG_INSTALL
AC_CHECK_PROG(RESCOMP, windres, windres)

ALL_LINGUAS="cs"
AM_GNU_GETTEXT

AC_ARG_ENABLE(debug, [  --enable-debug], DEBUG=$enableval, DEBUG="")
if test x$DEBUG = xyes; then
	AC_DEFINE(ENABLE_DEBUG, 1, [Define to 1 if debugging output is requested.])
fi

AC_ARG_ENABLE(semistatic, [  --enable-semistatic	build with static wxWindows library], SEMISTATIC=yes, SEMISTATIC=no)

AM_ACLOCAL_INCLUDE(m4)

AM_CHECK_EXPAT
AM_PATH_XML2(2.4.23, have_xml2=yes, have_xml2=no)
if test x$have_xml2 = xyes; then
    AM_PATH_XSLT(1.0.19, have_xslt=yes, have_xslt=no)
else
    have_xslt=no
fi
AM_OPTIONS_WXCONFIG
AM_PATH_WXCONFIG(2.4.0, wxWin=1)
if test "$wxWin" != 1; then
    AC_MSG_ERROR([
            wxWindows must be installed on your system
            but wx-config script couldn't be found.

            Please check that wx-config is in path, the directory
            where wxWindows libraries are installed (returned by
            'wx-config --libs' command) is in LD_LIBRARY_PATH or
            equivalent variable and wxWindows version is 2.4.0 or above.
    ])
fi

CPPFLAGS="$CPPFLAGS $WX_CPPFLAGS $EXPAT_CFLAGS"
CXXFLAGS="$CXXFLAGS $WX_CXXFLAGS_ONLY"
CFLAGS="$CFLAGS $WX_CFLAGS_ONLY $EXPAT_CFLAGS"

if test x$SEMISTATIC = xyes; then
    LIBS="$LIBS $WX_LIBS_STATIC $EXPAT_LIBS"
else
    LIBS="$LIBS $WX_LIBS $EXPAT_LIBS"
fi

if test x$have_xslt = xyes; then
    AC_DEFINE(HAVE_XSLT_SUPPORT, 1, [Defined to 1 iff we have libxslt so we can output SQL])
    CFLAGS="$CFLAGS $XSLT_CFLAGS"
    CPPFLAGS="$CPPFLAGS $XSLT_CFLAGS"
    CXXFLAGS="$CXXFLAGS $XSLT_CFLAGS"
    LIBS="$LIBS $XSLT_LIBS"
fi

dnl AC_CHECK_LIB(ogl, wxOGLInitialize, have_ogl=yes)

AM_CONDITIONAL(HAVE_OGL, test x$have_ogl = xyes)

dnl Test for Windows environment
if $WX_CONFIG_NAME --cxxflags | grep -q WXMSW; then
    use_windows=yes
    changequote(<<,>>)
    RC_WX_INCLUDES=`echo "$WX_CFLAGS" | sed -e 's/-[^I][^ ]*//g' | sed -e 's/-I\([^ ]*\)/--include-dir \1/g'`
    changequote([,])
else
    use_windows=no
fi
AM_CONDITIONAL(USE_WINDOWS, test x$use_windows = xyes)

AC_SUBST(RC_WX_INCLUDES)
AC_SUBST(CXXFLAGS)

AC_OUTPUT([
m4/Makefile 
Makefile
intl/Makefile
po/Makefile.in
po/Makefile
lib/Makefile
lib/wx-contrib/Makefile
lib/wx-contrib/src/Makefile
lib/wx-contrib/include/Makefile
lib/wx-contrib/include/wx/Makefile
lib/wx-contrib/include/wx/ogl/Makefile
lib/wx-contrib/src/ogl/Makefile
src/Makefile
src/bitmaps/Makefile
src/objects/Makefile
src/servers/Makefile
xsl/Makefile
win32/Makefile
datadesigner.spec
])