dnl $Id: configure.in,v 1.130 2006/10/07 15:14:02 cactus Exp $ -*- m4 -*-

dnl Guikachu
dnl Copyright (C) 2001-2005 �RDI Gerg�

dnl Process this file with autoconf to produce a configure script.
AC_PREREQ(2.50)
AC_INIT(src/guikachu.glade)
dnl AC_CONFIG_AUX_DIR(lib/scripts)

AM_CONFIG_HEADER(config.h)

VERSION=1.5.10
PACKAGE=guikachu

AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
AM_MAINTAINER_MODE
GUIKACHU_ACLOCAL_INCLUDE(lib/scripts)

dnl **********************
dnl Windows support
dnl **********************
AC_CANONICAL_HOST
AC_MSG_CHECKING([for host OS])
case "$host" in
	*-*-mingw*)
		GUIKACHU_HOST_OS="MinGW"
		;;
	*)
		GUIKACHU_HOST_OS="UNIX"
		;;
esac

AC_MSG_RESULT([$GUIKACHU_HOST_OS])
AM_CONDITIONAL(GUIKACHU_HOST_WIN32, test x$GUIKACHU_HOST_OS = xMinGW)


dnl **********************
dnl Internationalization
dnl **********************
GETTEXT_PACKAGE=$PACKAGE
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE", [Gettext package name])
AC_SUBST(GETTEXT_PACKAGE)

AM_GLIB_GNU_GETTEXT
IT_PROG_INTLTOOL([0.35.0])


dnl **********************
dnl C++ warnings, compile flags, and features
dnl **********************
AC_PROG_CXX
AC_PROG_RANLIB
CXX_NICE="$CXX $CXXFLAGS $LDFLAGS"
dnl GNOME_CXX_WARNINGS
CXXFLAGS="$CXXFLAGS -Wall"

GUIKACHU_CXX_VIRTUAL_TREE(
AC_MSG_ERROR([
The C++ compiler ($CXX_NICE) cannot seem to cope with the complicated
virtual inheritance tree of Guikachu. Consider using a more modern C++ compiler
(e.g. GCC 3.0)
]))

GUIKACHU_CXX_HASH_MAP


dnl **********************
dnl Perl modules
dnl **********************
GUIKACHU_PROG_PERL_XML


dnl **********************
dnl flex/yacc
dnl **********************
AM_PROG_LEX
AC_PROG_YACC


dnl **********************
dnl GNU M4 and Make
dnl **********************
GUIKACHU_PROG_GNU_M4(AC_MSG_ERROR([dnl
SUN m4 does not work for building foocanvasmm. 
Please install GNU m4.]))

GUIKACHU_PROG_GNU_MAKE(AC_MSG_ERROR([dnl
SUN make does not work for building foocanvasmm.
Please install GNU make.]))


dnl **********************
dnl freedesktop.org MIME database
dnl **********************
GUIKACHU_PROG_MIME

dnl **********************
dnl Check for library dependancies
dnl **********************
GUIKACHU_DEPS_GUIKACHU
GUIKACHU_DEPS_FOOCANVAS
GUIKACHU_DEPS_FOOCANVASMM


dnl **********************
dnl Check for optional build tools
dnl **********************
GUIKACHU_CHECK_OPTIONAL_PROG(PIXBUF_CSOURCE, gdk-pixbuf-csource, [gdk-pixbuf-csource not found, inline pixbufs will not be rebuilt])
GUIKACHU_CHECK_OPTIONAL_PROG(XSLTPROC, xsltproc, [HTML and DocBook documentation will not be rebuilt])
GUIKACHU_CHECK_OPTIONAL_PROG(ICOTOOL, icotool,	[icotool not found, Windows icons will not be rebuilt])
GUIKACHU_CHECK_OPTIONAL_PROG(WINDRES, windres, [windres not found])
if test "$GUIKACHU_HOST_OS" = MinGW -a "$WINDRES" = no
then
	AC_MSG_ERROR([windres needed for compiling Guikachu for Windows])
fi


dnl **********************
dnl GConf
dnl **********************
if test x$have_gconf = xyes; then
	GUIKACHU_PROG_GCONFTOOL
	AM_GCONF_SOURCE_2
else
	AM_CONDITIONAL(GCONF_SCHEMAS_INSTALL, false)
fi


dnl **********************
dnl Data shared by various subdirs
dnl **********************
FONTS="stdfont boldfont bigfont symbol symbol7 symbol11 ledfont bigbold"
AC_SUBST(FONTS)


dnl **********************
dnl Funny checks
dnl **********************
AC_MSG_CHECKING(for Bugemons on the loose)
sleep 1
AC_MSG_RESULT(catching them all)


dnl **********************
dnl Create Makefiles
dnl **********************
AC_OUTPUT([
	Makefile

	lib/Makefile
	lib/scripts/Makefile

	lib/foocanvas/Makefile
	lib/foocanvas/libfoocanvas/Makefile

	lib/foocanvasmm/Makefile
	lib/foocanvasmm/foocanvas/Makefile
	lib/foocanvasmm/foocanvas/src/Makefile
	lib/foocanvasmm/foocanvas/foocanvasmm/Makefile
        lib/foocanvasmm/foocanvas/foocanvasmm/private/Makefile
	lib/foocanvasmm/tools/Makefile
	lib/foocanvasmm/tools/m4/Makefile

	src/Makefile
	src/pixmaps/Makefile
	src/form-editor/Makefile
	src/widgets/Makefile
	src/io/Makefile
	src/io/xml/Makefile
	src/io/rcp/Makefile

	data/Makefile
	fonts/Makefile

	doc/Makefile
	doc/pictures/Makefile
	doc/xsl/Makefile
	doc/xsl/html/Makefile
	doc/xsl/docbook/Makefile

	po/Makefile.in

	examples/Makefile

	guikachu.spec
	guikachu.nsi
])

cat << EOF

This is the experimental GNOME 2 branch of Guikachu. The latest
production release line is the 1.4 series. To obtain 1.4, either
download it from http://cactus.rulez.org/projects/guikachu/ or get the
stable branch from CVS:
       cvs get -r guikachu-1_4-branch
       
EOF