# Configure.in
#
#  This file tests for various compiler features needed to configure 
#  the gtkmm package.  Original skeleton was provided by Stephan Kulow.
#  All tests were written by Tero Pulkkinen, Mirko Streckenbach, and 
#  Karl Nelson.
#
#  NOTE! IF YOU DO CHANGES HERE, CHECK IF YOU NEED TO MODIFY .m4 TOO!!!
#
#  Copyright 2001 Free Software Foundation
#  Copyright 1999 gtkmm Development Team
#  Copyright 1998 Stephan Kulow 
#
AC_INIT(libglade/libglademmconfig.h.in)

#########################################################################
#  Version and initialization
#########################################################################
LIBGLADEMM_MAJOR_VERSION=2
LIBGLADEMM_MINOR_VERSION=1
LIBGLADEMM_MICRO_VERSION=3

#
# +1 : ? : +1  == new interface that does not break old one
# +1 : ? : 0   == new interface that breaks old one
#  ? : ? : 0   == no new interfaces, but breaks apps
#  ? :+1 : ?   == just some internal changes, nothing breaks but might work
#                 better
# CURRENT : REVISION : AGE
LIBGLADEMM_SO_VERSION=1:5:0

LIBGLADEMM_VERSION=$LIBGLADEMM_MAJOR_VERSION.$LIBGLADEMM_MINOR_VERSION.$LIBGLADEMM_MICRO_VERSION
LIBGLADEMM_RELEASE=$LIBGLADEMM_MAJOR_VERSION.$LIBGLADEMM_MINOR_VERSION
AC_DEFINE_UNQUOTED(LIBGLADEMM_MAJOR_VERSION, $LIBGLADEMM_MAJOR_VERSION)
AC_DEFINE_UNQUOTED(LIBGLADEMM_MINOR_VERSION, $LIBGLADEMM_MINOR_VERSION)
AC_DEFINE_UNQUOTED(LIBGLADEMM_MICRO_VERSION, $LIBGLADEMM_MICRO_VERSION)
AC_DEFINE_UNQUOTED(LIBGLADEMM_VERSION, "$LIBGLADEMM_VERSION")
AC_SUBST(LIBGLADEMM_VERSION)
AC_SUBST(LIBGLADEMM_RELEASE)
AC_SUBST(LIBGLADEMM_SO_VERSION)

AC_CONFIG_AUX_DIR(scripts)

dnl For automake.
VERSION=$LIBGLADEMM_VERSION
PACKAGE=libglademm

dnl Initialize automake stuff
AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl Specify a configuration file (no autoheader)
AM_CONFIG_HEADER(libglade/libglademmconfig.h)
AM_MAINTAINER_MODE
AL_ACLOCAL_INCLUDE(scripts)


#########################################################################
#  Configure arguments
#########################################################################

#########################################################################
#  Environment Checks
#########################################################################
AC_PROG_CC
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_CANONICAL_HOST
AM_DISABLE_STATIC
AC_LIBTOOL_WIN32_DLL
AM_PROG_LIBTOOL

dnl Used for enabling the "-no-undefined" and "-export-all-symbols" flags 
dnl while generating DLLs. Borrowed from the official gtk+-2 configure.in
AC_MSG_CHECKING([for some Win32 platform])
case "$host" in
  *-*-mingw*|*-*-cygwin*)
    platform_win32=yes
    ;;
  *)
    platform_win32=no
    ;;
esac
AC_MSG_RESULT([$platform_win32])
AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")

AL_PROG_GNU_M4(AC_MSG_ERROR([dnl
SUN m4 does not work for building gtkmm.
Please install GNU m4.]))

AL_PROG_GNU_MAKE(AC_MSG_ERROR([dnl
SUN make does not work for building gtkmm.
Please install GNU make.]))

#########################################################################
#  Dependancy checks
#########################################################################

# Make LIBGLADE_VERSION_NEEDED available to both PKG_CHECK_MODULES(), the .pc.in file, and init.cc:
LIBGLADE_VERSION_NEEDED=1.99.11
AC_SUBST(LIBGLADE_VERSION_NEEDED)
AC_DEFINE_UNQUOTED(LIBGLADE_VERSION_NEEDED_QUOTED, "$LIBGLADE_VERSION_NEEDED")

# Make these available to both PKG_CHECK_MODULES and the .pc.in file:
GTKMM_VERSION_NEEDED=2.0.2
AC_SUBST(GTKMM_VERSION_NEEDED)

PKG_CHECK_MODULES(LIBGLADEMM, gtkmm-2.0 >= $GTKMM_VERSION_NEEDED libglade-2.0 >= $LIBGLADE_VERSION_NEEDED)
AC_SUBST(LIBGLADEMM_CFLAGS)
AC_SUBST(LIBGLADEMM_LIBS)

GTKMM_PREFIX=`pkg-config --variable=prefix gtkmm-2.0`
GTKMM_PROCDIR=$GTKMM_PREFIX/lib/gtkmm-2.0/proc
AC_SUBST(GTKMM_PROCDIR)
GTKMM_PROC=$GTKMM_PROCDIR/gtkmmproc
AC_SUBST(GTKMM_PROC)

#########################################################################
#  C++ checks
#########################################################################
AC_PROG_CXX
AC_LANG_CPLUSPLUS


# Create a list of input directories for Doxygen.  We have to check wether
# we are building in the source directory, because Doxygen doesn't like
# duplicated directories in the input list.
LIBGLADEMM_DOXYGEN_INPUT=''
gtkmm_srcdir=`cd "$srcdir" && pwd`
gtkmm_builddir=`pwd`
for sublib in libglade
do
  LIBGLADEMM_DOXYGEN_INPUT="$LIBGLADEMM_DOXYGEN_INPUT $gtkmm_builddir/$sublib/$sublib""mm/"
  test "x$gtkmm_builddir" = "x$gtkmm_srcdir" || \
    LIBGLADEMM_DOXYGEN_INPUT="$LIBGLADEMM_DOXYGEN_INPUT $gtkmm_srcdir/$sublib/$sublib""mm/"
done
AC_SUBST(LIBGLADEMM_DOXYGEN_INPUT)


# Used in build_shared/Makefile_gensrc.am_fragment:
GTKMMPROC_MERGECDOCS=''
test "x$gtkmm_enable_fulldocs" = "xyes" && GTKMMPROC_MERGECDOCS='--mergecdocs'
AC_SUBST(GTKMMPROC_MERGECDOCS)

# Dummy conditional just to make automake-1.4 happy.
# We need an always-false condition in docs/Makefile.am.
AM_CONDITIONAL(LIBGLADEMM_FALSE,[false])

# HACK:  Assign a dummy in order to prevent execution of autoheader by the
# maintainer-mode rules.  That would fail since we aren't using autoheader.
AUTOHEADER=':'


AC_OUTPUT([
	Makefile

	libglade/Makefile
	libglade/libglademm-2.0.pc
	libglade/libglademm-2.0-uninstalled.pc
	libglade/src/Makefile
	libglade/libglademm/Makefile
	libglade/libglademm/private/Makefile
	
	tools/Makefile
		tools/extra_defs_gen/Makefile
		tools/m4/Makefile

	examples/Makefile
		examples/basic/Makefile
		examples/derived/Makefile
                examples/menus/Makefile
                examples/variablesmap/Makefile

	scripts/Makefile

	docs/Makefile
	docs/reference/Makefile
	docs/reference/Doxyfile
	libglademm.spec
])