### Normal initialization. ######################################
AC_INIT([fget], [1.3.3])
AC_PREREQ([2.57])
AC_CONFIG_AUX_DIR([autoconf])
AC_CONFIG_HEADERS([config.h])
AC_COPYRIGHT([[
Copyright (c) 2000-2004 University of Illinois Board of Trustees
Copyright (c) 2000-2005 Mark D. Roth
All rights reserved.
]])
AC_CONFIG_SRCDIR([fget/fget.c])
ENCAP_PKG


### Set some option defaults. ###################################
if test -z "$CFLAGS"; then
  CFLAGS="-O"
fi
MKDIR="mkdir -p -m 755"
AC_SUBST([MKDIR])


### Check for compiler et al. ###################################
AC_PROG_CC
AC_PROG_RANLIB
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET


### Compiler characteristics. ##################################
AC_AIX
AC_C_CONST


### Checks for header files. ###################################
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS([unistd.h inttypes.h])
AC_HEADER_MAJOR
PSG_REPLACE_TYPE([major_t], [unsigned int], [
  #include <sys/types.h>
  #ifdef MAJOR_IN_MKDEV
  # include <sys/mkdev.h>
  #else
  # ifdef MAJOR_IN_SYSMACROS
  #  include <sys/sysmacros.h>
  # endif
  #endif
])
PSG_REPLACE_TYPE([minor_t], [unsigned int], [
  #include <sys/types.h>
  #ifdef MAJOR_IN_MKDEV
  # include <sys/mkdev.h>
  #else
  # ifdef MAJOR_IN_SYSMACROS
  #  include <sys/sysmacros.h>
  # endif
  #endif
])
PSG_REPLACE_TYPE([dev_t], [unsigned long], [
  #include <sys/types.h>
  #ifdef MAJOR_IN_MKDEV
  # include <sys/mkdev.h>
  #else
  # ifdef MAJOR_IN_SYSMACROS
  #  include <sys/sysmacros.h>
  # endif
  #endif
])
PSG_REPLACE_TYPE([uint64_t], [long long])
AC_TYPE_MODE_T
AC_TYPE_OFF_T
AC_TYPE_SIZE_T
AC_TYPE_UID_T
PSG_REPLACE_TYPE([nlink_t], [unsigned short])


### Checks for needed functions. ###############################
PSG_MODULE([compat])
COMPAT_FUNC_BASENAME
COMPAT_FUNC_DIRNAME
COMPAT_FUNC_FNMATCH
COMPAT_FUNC_GETHOSTNAME
AC_CHECK_FUNCS([localtime_r])
if test "$ac_cv_func_localtime_r" != "yes"; then
  AC_MSG_WARN([cannot find localtime_r - resulting libraries will not be thread-safe])
else
  COMPAT_PROTO_MACRO([localtime_r], [time.h], [_REENTRANT _THREAD_SAFE])
fi
AC_CHECK_FUNCS([lchown])
COMPAT_FUNC_SNPRINTF
COMPAT_FUNC_STRDUP
COMPAT_FUNC_STRLCAT
COMPAT_FUNC_STRLCPY
COMPAT_FUNC_STRMODE
COMPAT_FUNC_STRSEP


### Create output files. #######################################
PSG_MODULE([netio])
PSG_MODULE([listhash])
PSG_MODULE([pathcode])
AC_CONFIG_FILES([Makefile lib/Makefile fget/Makefile doc/Makefile test/Makefile])
AC_OUTPUT