TEMPLATE	= app
CONFIG	       += qt warn_on

exists( $(QTDIR)/lib/libqt-mt* ) {
    message( "Configuring for multi-threaded Qt..." )
    CONFIG += thread
}

UI_DIR		= .ui
MOC_DIR		= .moc
OBJECTS_DIR	= .obj

HEADERS		= cell.h	\
		  mainwindow.h

SOURCES		= cell.cpp	\
		  main.cpp	\
		  mainwindow.cpp

IMAGES		= pics/background.png	\
		  pics/cable0001.png	\
		  pics/cable0010.png	\
	          pics/cable0011.png	\
	          pics/cable0100.png	\
	          pics/cable0101.png	\
	          pics/cable0110.png	\
	          pics/cable0111.png	\
	          pics/cable1000.png	\
	          pics/cable1001.png	\
	          pics/cable1010.png	\
	          pics/cable1011.png	\
	          pics/cable1100.png	\
	          pics/cable1101.png	\
	          pics/cable1110.png	\
	          pics/computer1.png	\
	          pics/computer2.png	\
	          pics/highscores.png	\
	          pics/homepage.png	\
	          pics/newgame.png	\
	          pics/qnetwalk.png	\
	          pics/quit.png		\
	          pics/server.png

TRANSLATIONS    = translations/qnetwalk_de.ts	\
		  translations/qnetwalk_es.ts	\
		  translations/qnetwalk_fr.ts	\
	          translations/qnetwalk_nl.ts	\
	          translations/qnetwalk_pl.ts	\
	          translations/qnetwalk_pt_BR.ts \
	          translations/qnetwalk_ru.ts

TARGET		= qnetwalk
target.path	= /usr/local/bin
INSTALLS       += target

man.path	= /usr/local/man/man6
man.files	= qnetwalk.6
INSTALLS       += man

tr.path		= /usr/local/share/qnetwalk/translations
tr.files	= translations/*.qm
INSTALLS       += tr

sounds.path	= /usr/local/share/qnetwalk/sounds
sounds.files	= sounds/*.wav
INSTALLS       += sounds

KDEROOT = $$(KDEDIR)

isEmpty( KDEROOT ) {
    KDEROOT = /usr
}

link.path	= $$KDEROOT/share/applnk/Games
link.files	= qnetwalk.desktop
INSTALLS       += link

icon.path	= $$KDEROOT/share/icons/hicolor/16x16/apps
icon.files	= pics/qnetwalk.png
INSTALLS       += icon