~

  Character Script: Random NPC

~





~

  Death Script

~
if $KILLED = 'Yes'

  ~ do nothing ~

end_if

~ Death Script End ~





~

  Dialogue Script

~
if $TRIGGERED = 'Yes'

~
  collecting dialogue determining data
~
character_power_rating $self_power $SELF

character_has_perk $has_persuade $ACTIVE_CHARACTER 'Persuade'
party_power_rating $recruiting_power
party_n_members $party_size



~ the persuade perk boosts recruiting power ~
if $has_persuade = 'Yes'
  expr $recruiting_power $recruiting_power 2 *
end_if



~
  the passive character greets
~
dialogue_say 'Hello.'



~
  dialogue loop
~
loop


  if $choice = 'Farewell.'
    break
  end_if

  ~ subject to change, so we need to check this here ~ 
  party_is_member $self_party_member $SELF

  ~
    the active character's dialogue options
  ~
  dialogue_add_option 'What is the current situation like?'
  dialogue_add_option 'I want to buy something.'

  if $self_party_member = 'Yes'
    dialogue_add_option 'Leave the party.'
  else 
    dialogue_add_option 'Join me!'
  end_if

  dialogue_add_option 'Farewell.'


  ~
    dialogue choice
  ~
  dialogue_choice $choice


  ~
    the passive character replies
  ~
  if $choice = 'What is the current situation like?'

    dialogue_say 'All levels below level 12 are under enemy control.'

  else_if $choice = 'I want to buy something.'

    dialogue_say 'We are all about to be killed, and you want to go shopping?! '
    dialogue_say 'Well, most shops have been destroyed, but you can try looking '
    dialogue_say 'for Schweitzer or Deco. Schweitzer sells his homemade drugs, '
    dialogue_say 'and Deco sells.. whatever he can find. '
    dialogue_say 'Schweitzer\'s \'shop\' is on level 12. Only the Emperor '
    dialogue_say 'knows where Deco is right now.'

  else_if $choice = 'Join me!'

    if $party_size = 3

      dialogue_say 'I think your party is big enough already.'

    else_if $recruiting_power < $self_power

      dialogue_say 'No, your party looks weak.'

    else

      dialogue_say 'Ok.'

      party_join $SELF

    end_if

  else_if $choice = 'Leave the party.'
   
    dialogue_say 'Ok.' 
    party_leave $SELF

  end_if


end_loop

end_if

~ Dialogue Script End ~