# configure.in for gtkDPS-0.x
#
# Author: Masatake YAMATO (masata-y@is.aist-nara.ac.jp), GYVE Development Team
# This is part of gtkDPS library.
#

AC_INIT(gtkDPS/gtkDPS.h)
. $srcdir/GTKDPS-VERSION

AC_CANONICAL_SYSTEM
AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

AM_CONFIG_HEADER(config.h)

AC_DEFUN(AC_GTK_CHECK,
[AM_PATH_GTK(1.2.6,, AC_MSG_ERROR(Cannot find gtk: see config.log.))
X_LIBS=$GTK_LIBS
X_CFLAGS=$GTK_CFLAGS
AC_SUBST(GTK_LIBS)
AC_SUBST(GTK_CFLAGS)])

AC_DEFUN(AC_DPS_CHECK,
[AC_PATH_DPSET
if test "x$no_dps" = xyes ; then
	AC_MSG_ERROR(Could not find the dps client library: see config.log)
fi
AC_SUBST(DPS_CFLAGS)
AC_SUBST(DPS_LIBS)
])

#--------------------------------------------------------------------
# Find the compiler
#--------------------------------------------------------------------
AC_PROG_CC
AC_ISC_POSIX
AC_PROG_CPP
AM_PROG_LIBTOOL
AC_PROG_MAKE_SET
AC_PROG_INSTALL
AC_ARG_PROGRAM
AC_CHECK_PROG(PSWRAP_FOUND, pswrap, yes, no)
if test "$PSWRAP_FOUND" = no; then
	AC_MSG_ERROR(Colud not find the pswrap translator: see config.log)
fi

if test "x$GCC" = "xyes"; then
  if test -z "`echo "$CFLAGS" | grep "\-Wall" 2> /dev/null`" ; then
    CFLAGS="$CFLAGS -Wall"
  fi

  if test "x$enable_ansi" = "xyes"; then
    if test -z "`echo "$CFLAGS" | grep "\-ansi" 2> /dev/null`" ; then
      CFLAGS="$CFLAGS -ansi"
    fi

    if test -z "`echo "$CFLAGS" | grep "\-pedantic" 2> /dev/null`" ; then
      CFLAGS="$CFLAGS -pedantic"
    fi
  fi
fi


dnl Checks for libraries.
dnl Replace `main' with a function in -lm:
AC_CHECK_LIB(m, main)

dnl Checks for header files.
AC_HEADER_DIRENT
AC_HEADER_STDC

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST

#--------------------------------------------------------------------
# GTK
#--------------------------------------------------------------------
AC_GTK_CHECK

#i18n stuff

ALL_LINGUAS="ja"
AM_GTK_GNU_GETTEXT
LIBS="$LIBS $INTLLIBS"
gtkdpslocaledir='${prefix}/${DATADIRNAME}/locale'
AC_SUBST(gtkdpslocaledir)

#--------------------------------------------------------------------
# DPS 
#--------------------------------------------------------------------
AC_DPS_CHECK

#--------------------------------------------------------------------
# gtkDPS.spec --- automatic rpm generating
#--------------------------------------------------------------------
dnl
dnl AC_ARG_RPM_PREFIX
dnl 
AC_DEFUN(AC_ARG_RPM_PREFIX,
[dnl
run_config_date=`date +%Y%m%d`
AC_SUBST(run_config_date)
AC_ARG_WITH(rpm_prefix, [  --with-rpm-prefix=RPATH  Prefix for RPM. [/usr]], 
	                           rpm_prefix=$withval,
				   rpm_prefix=/usr)
AC_SUBST(rpm_prefix)]) 
dnl
AC_ARG_RPM_PREFIX
dnl
AC_SUBST(dps_includes)
AC_SUBST(dps_libraries)
dnl
# tarball_topdir=`pwd | sed 's%^.*/%%'`
# AC_SUBST(tarball_topdir)
# AC_SUBST(PATH)
# AC_SUBST(LD_LIBRARY_PATH)

AC_CHECK_FUNCS(floorf)
AC_CHECK_FUNCS(ceilf)
#--------------------------------------------------------------------
# Generate files
#--------------------------------------------------------------------
AC_OUTPUT([Makefile gtkDPS/Makefile gtkDPS-config gtkDPS.spec po/Makefile.in
intl/Makefile
],[chmod +x gtkDPS-config])