# Process this file with autoconf to produce a configure script.
AC_INIT(Passepartout, 0.7.0, [http://bugzilla.gnome.org/simple-bug-guide.cgi?product=passepartout])
AC_CONFIG_SRCDIR([src/xml2ps/blockcontainer.cc])

AM_INIT_AUTOMAKE([foreign dist-bzip2])
# For automake < 1.6 you need to use this line instead:
#AM_INIT_AUTOMAKE(Passepartout, 0.7-PRE)

AM_CONFIG_HEADER(src/defines.h)
# AC_CONFIG_HEADER(src/defines.h)

# Define global compiler flags:
MY_CXXFLAGS="-Wall"
CXXFLAGS="$CXXFLAGS $MY_CXXFLAGS"

# Checks for programs.
AC_PROG_CXX
AC_PROG_RANLIB

# AC_APPLY_RPATH(LIBS)
# --------------------
# Add an -rpath linker option for each -L path in LIBS
# if and only if the environment variable APPLY_RPATH is set
AC_DEFUN([AC_APPLY_RPATH],
[if test "$APPLY_RPATH" != ""; then
  $1=`echo "[$]$1" | [sed -e "s/-L\([^ ]*\)/& -Wl,-rpath,\1/g"]`
fi])
AC_ARG_VAR([APPLY_RPATH], [="true" : specify -rpath options to the linker])

# check for libxml++ 
AC_SUBST([XMLPP_LIBS])
AC_SUBST([XMLPP_CFLAGS])
PKG_CHECK_MODULES([XMLPP], libxml++-1.0 >= 1.0)
AC_APPLY_RPATH([XMLPP_LIBS])

AC_SUBST([GTKMM_LIBS])
AC_SUBST([GTKMM_CFLAGS])
PKG_CHECK_MODULES(GTKMM, gtkmm-2.4)
AC_APPLY_RPATH([GTKMM_LIBS])

AC_SUBST([GNOMECANVAS_LIBS])
AC_SUBST([GNOMECANVAS_CFLAGS])
PKG_CHECK_MODULES(GNOMECANVAS, libgnomecanvasmm-2.6)
AC_APPLY_RPATH([GNOMECANVAS_LIBS])

AC_SUBST([GTHREAD_LIBS])
AC_SUBST([GTHREAD_CFLAGS])
PKG_CHECK_MODULES([GTHREAD], [gthread-2.0])
AC_APPLY_RPATH([GTHREAD_LIBS])

AC_SUBST([FREETYPE_LIBS])
AC_SUBST([FREETYPE_CFLAGS])
PKG_CHECK_MODULES([FREETYPE], [freetype2])
AC_APPLY_RPATH([FREETYPE_LIBS])

# gnome is optional
AC_SUBST([GNOME_LIBS])
AC_SUBST([GNOME_CFLAGS])
AC_SUBST([GNOMEVFS_LIBS])
AC_SUBST([GNOMEVFS_CFLAGS])
AC_ARG_WITH([gnome], AC_HELP_STRING([--with-gnome],
                                    [Gnome support (default is NO)]),
            [PKG_CHECK_MODULES(GNOME, libgnome-2.0)]
            [PKG_CHECK_MODULES(GNOMEVFS, gnome-vfs-module-2.0)]
            AC_DEFINE([HAVE_GNOME], [1], [Gnome is present]))
AC_APPLY_RPATH([GNOME_LIBS])
AC_APPLY_RPATH([GNOMEVFS_LIBS])

# check for fam
AC_CHECK_LIB([fam], [FAMOpen])

# $(datadir) has to be expanded by make
# path to install docs in
AC_SUBST(docdir, ['"$(datadir)/doc/$(PACKAGE)/"'])
# path to install xml stuff in
AC_SUBST(xmldir, ['"$(datadir)/xml/$(PACKAGE)/"'])

# Checks for header files.
AC_HEADER_DIRENT

# Checks for typedefs, structures, and compiler characteristics.
AC_TYPE_PID_T
AC_TYPE_SIZE_T

# Checks for library functions.
AC_FUNC_FORK
AC_FUNC_STAT
AC_CHECK_FUNCS([realpath strdup mkdtemp])

AC_CONFIG_FILES([Makefile
	         src/Makefile	
                 src/ps/Makefile
                 src/util/Makefile
                 src/testbed/Makefile
		 src/fonts/Makefile
		 src/pptout/Makefile
                 src/pptout/document/Makefile
                 src/pptout/widget/Makefile
                 src/pptout/icons/Makefile
                 src/xml2ps/Makefile
		 doc/Makefile
		 doc/examples/Makefile
		 logotype/Makefile])
AC_OUTPUT