dnl Process this file with autoconf to produce a configure script.
AC_INIT
AC_CANONICAL_TARGET([])
AC_SUBST(target)

case $host in
  *-*-linux* | *-*-mingw32* | *-*-freebsd*)
  ;;
  *)
  AC_MSG_WARN([*** ix86 linux, MingW32 and FreeBSD are the only tested platforms ***])
  ;;
esac

dnl set the package and version
ofc_MAJOR=0
ofc_MINOR=8
ofc_MICRO=0
ofc_VERSION=$ofc_MAJOR.$ofc_MINOR.$ofc_MICRO

AC_SUBST(ofc_MAJOR)
AC_SUBST(ofc_MINOR)
AC_SUBST(ofc_MICRO)
AC_SUBST(ofc_VERSION)

dnl libtool version info - taken gratefully from the SDL and GTK sources
dnl
dnl Making releases:
dnl   ofc_MINOR         += 1; or
dnl   ofc_MICRO         += 1;
dnl   ofc_INTERFACE_AGE += 1;
dnl   ofc_BINARY_AGE    += 1;
dnl if any functions have been added, set ofc_INTERFACE_AGE to 0.
dnl if backwards compatibility has been broken,
dnl set ofc_BINARY_AGE and ofc_INTERFACE_AGE to 0.
ofc_INTERFACE_AGE=0
ofc_BINARY_AGE=0

AC_SUBST(ofc_INTERFACE_AGE)
AC_SUBST(ofc_BINARY_AGE)

LT_RELEASE=$ofc_MAJOR.$ofc_MINOR
LT_CURRENT=`expr $ofc_MICRO - $ofc_INTERFACE_AGE`
LT_REVISION=$ofc_INTERFACE_AGE
LT_AGE=`expr $ofc_BINARY_AGE - $ofc_INTERFACE_AGE`

AC_SUBST(LT_RELEASE)
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)

VERSION=$ofc_VERSION
PACKAGE=ofc

OFC_CFLAGS=""
OFC_LIB=""
SHARED_LIBS=""
STATIC_LIBS=""

dnl Checks for programs.
AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
AC_CONFIG_HEADERS([ofc/settings.h])

dnl Check CFLAGS
if test -z "${CFLAGS}"; then
  CFLAGS="-O2 -Wall -fno-strict-aliasing"
  OFC_CFLAGS="-fno-strict-aliasing"  
fi

dnl Test different systems
case $host_os in
  *mingw32* ) MINGW32=yes;;
	  * ) MINGW32=no;;
esac

case $host_os in
  *cygwin* ) CYGWIN=yes;;
	 * ) CYGWIN=no;;
esac

dnl case $host_os in
dnl  darwin* )
dnl    OFC_CFLAGS="${OFC_CFLAGS} -fgnu-runtime"
dnl esac

AC_PROG_CC

if test "$CC" != "gcc"; then
  AC_MSG_WARN([*** Only gcc compiler is tested ***])
fi

dnl Disable shared libraries during development
dnl AC_DISABLE_SHARED


AC_PROG_MAKE_SET
AC_PROG_INSTALL
AC_PROG_LN_S
dnl AC_PROG_RANLIB
AM_PROG_LIBTOOL

dnl Check for endian
AC_C_BIGENDIAN


dnl Checks for libraries.
AC_CHECK_LIB(pthread, pthread_create)
AC_CHECK_LIB(objc, objc_malloc)
AC_CHECK_LIB(m, asin)
AC_CHECK_LIB(gdbm, gdbm_open)
AC_CHECK_LIB(regex, re_match)
AC_CHECK_LIB(gnuregex, re_match)
AC_CHECK_LIB(expat, XML_SetNamespaceDeclHandler)
AC_CHECK_LIB(z, gzopen)
AC_CHECK_LIB(gmp, __gmpz_init)
AC_CHECK_LIB(bz2, BZ2_bzReadOpen)
AC_CHECK_LIB(ncurses, initscr)
AC_CHECK_LIB(png, png_sig_cmp)
AC_CHECK_LIB(jpeg, jpeg_read_header)

if test "x$CYGWIN" = "xyes" -o "x$MINGW32" = "xyes" ; then
LIBS="-lwsock32 ${LIBS}"
fi

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(limits.h sys/time.h unistd.h regex.h gnu/regex.h gdbm.h \
expat.h zlib.h syslog.h gmp.h bzlib.h ncurses.h png.h jpeglib.h)

dnl Checks for SDL
SDL_CFLAGS=""
SDL_LIBS=""
SDL_SLIBS=""
AC_CHECK_PROGS(HAS_SDL, sdl-config)
if test "x$HAS_SDL" != "x"; then
  SDL_CFLAGS=`sdl-config --cflags`
  SDL_LIBS=`sdl-config --libs`
  SDL_SLIBS=`sdl-config --libs`
  HAS_SDL=1
else
  HAS_SDL=0
fi  
AC_DEFINE_UNQUOTED(HAS_SDL, $HAS_SDL, [Define 1 if SDL is present])

dnl Checks for FreeType2
FT_CFLAGS=""
FT_LIBS=""
FT_SLIBS=""
AC_CHECK_PROGS(HAS_FREETYPE, freetype-config)
if test "x$HAS_FREETYPE" != "x"; then
  FT_CFLAGS=`freetype-config --cflags`
  FT_LIBS=`freetype-config --libs`
  FT_SLIBS=`freetype-config --libs`
  HAS_FREETYPE=1
else
  HAS_FREETYPE=0
fi  
AC_DEFINE_UNQUOTED(HAS_FREETYPE, $HAS_FREETYPE, [Define 1 if FreeType is present])

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_HEADER_TIME
AC_STRUCT_TM

dnl Checks for library functions.
AC_FUNC_MEMCMP
AC_FUNC_STRFTIME
AC_CHECK_FUNCS(gettimeofday mktime select strtod strtol re_match strptime)

dnl Check for warnings support
AC_MSG_CHECKING([Warnings support])
AC_ARG_ENABLE(warnings,[  --disable-warnings      compile without warnings])
AC_MSG_RESULT([$enable_warnings])
if test "x$enable_warnings" != "xno"; then
  ENABLE_WARNINGS=1
else
  ENABLE_WARNINGS=0
fi
AC_DEFINE_UNQUOTED(ENABLE_WARNINGS, $ENABLE_WARNINGS, [Enable warning message])

dnl Check for debugging support
AC_MSG_CHECKING([for debugging])
AC_ARG_ENABLE(debug,[  --enable-debug          compile with debug info])
AC_MSG_RESULT([$enable_debug])
if test "x$enable_debug"  == "xyes"; then
  CFLAGS="-g ${CFLAGS}"
  OFC_CFLAGS="-g ${OFC_CFLAGS}"
fi

OBJC=${CC}
OBJCFLAGS="${CFLAGS} ${SDL_CFLAGS} ${FT_CFLAGS} -fgnu-runtime"
OFC_CFLAGS="${OFC_CFLAGS} ${SDL_CFLAGS} ${FT_CFLAGS} -fgnu-runtime"
OFC_LIB="-lofc"
SHARED_LIBS="${SDL_LIBS} ${FT_LIBS} ${LIBS}"
dnl STATIC_LIBS="${SDL_SLIBS} ${FT_SLIBS} ${LIBS}"
STATIC_LIBS="${SDL_LIBS} ${FT_LIBS} ${LIBS}"
LIBS="${SDL_LIBS} ${FT_LIBS} ${LIBS}"

_AM_DEPENDENCIES([OBJC])

AC_SUBST(OBJC)
AC_SUBST(OBJCFLAGS)

AC_SUBST(OFC_CFLAGS)
AC_SUBST(OFC_LIB)
AC_SUBST(SHARED_LIBS)
AC_SUBST(STATIC_LIBS)

AC_CONFIG_FILES([Makefile ofc/Makefile test/Makefile tex/Makefile bin/ofc-config])
AC_OUTPUT

dnl Done.
echo "
Configuration:
  Source code location: ${srcdir}
  Obj-c Compiler:       ${OBJC} ${OBJCFLAGS}
  C Compiler:           ${CC} ${CFLAGS}
  Host System Type:     ${host}
  Install path:         ${prefix}
  Libraries:            ${LIBS}
  
Do: 'make' to start the compilation.
"