dnl
dnl  WMMail - Window Maker Mail
dnl
dnl  Copyright (c) 1996, 1997, 1998  Per Liden
dnl  Copyright (c) 1997, 1998  Bryan Chan
dnl
dnl  This program is free software; you can redistribute it and/or modify
dnl  it under the terms of the GNU General Public License as published by
dnl  the Free Software Foundation; either version 2 of the License, or
dnl  (at your option) any later version.
dnl 
dnl  This program is distributed in the hope that it will be useful,
dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl  GNU General Public License for more details.
dnl 
dnl  You should have received a copy of the GNU General Public License
dnl  along with this program; if not, write to the Free Software
dnl  Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
dnl
dnl  configure.in: run autoconf on this file to produce a configure script
dnl
dnl  $Id: configure.in,v 1.10 2000/07/02 20:40:42 bryan.chan Exp $
dnl

AC_INIT(src/wmmail.c)
AC_PROG_MAKE_SET

PACKAGE=WMMail
AC_SUBST(PACKAGE)

VERSION=0.64
AC_SUBST(VERSION)

dnl
dnl  check for programs
dnl
AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S

AC_ARG_PROGRAM

AC_PATH_PROG(AUTOCONF, autoconf)
AC_PATH_PROG(ACLOCAL, aclocal)
AC_PATH_PROG(AUTOHEADER, autoheader)
AC_PATH_PROG(AUTOMAKE, automake)


dnl
dnl  look for X Window first before further lib checks
dnl
AC_PATH_X 

if test "$x_includes" != "NONE"; then
        CFLAGS="$CFLAGS -I$x_includes"
fi

if test "$x_libraries" != "NONE"; then
        LDFLAGS="$LDFLAGS -L$x_libraries"
fi


dnl
dnl  get compiler flags for libPropList and Window Maker
dnl
AC_ARG_WITH(PL-libs, [  --with-PL-libs	  pass compiler flags to find libPropList libraries], [PLLIBS=$withval], [PLLIBS=""])

AC_ARG_WITH(PL-incs, [  --with-PL-incs	  pass compiler flags to find libPropList header files], [PLINCS=$withval], [PLINCS=""])

AC_ARG_WITH(WM-libs, [  --with-WM-libs	  pass compiler flags to find Window Maker libraries], [WMLIBS=$withval], [WMLIBS=""])

AC_ARG_WITH(WM-incs, [  --with-WM-incs	  pass compiler flags to find Window Maker header files], [WMINCS=$withval], [WMINCS=""])

CFLAGS="$CFLAGS $PLINCS $WMINCS"
LDFLAGS="$LDFLAGS $PLLIBS $WMLIBS"


dnl
dnl  installation point (/usr/local/GNUstep/Apps/WMMail.app by default),
dnl  with support for GNUSTEP_LOCAL_ROOT
dnl
appspath=""

AC_ARG_WITH(appspath, [  --with-appspath	  specify the GNUstep applications directory], appspath=$withval)

if test "x$appspath" = "x"; then
  gnustepdir='$(prefix)/GNUstep'

  if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
    gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
    gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
  fi

  appspath=$gnustepdir/Apps
fi

wmmaildir=$appspath/WMMail.app

AC_SUBST(wmmaildir)


dnl
dnl  enabling/disabling components
dnl
AC_ARG_ENABLE(mbox, [  --disable-mbox	  disable UNIX mbox support], , enable_mbox=yes)
if test "$enable_mbox" = yes; then
  MBOX_SUPPORT="#define MBOX_SUPPORT"
else
  MBOX_SUPPORT="#undef MBOX_SUPPORT"
fi
AC_SUBST(MBOX_SUPPORT)

AC_ARG_ENABLE(mh, [  --disable-mh		  disable mh folder support], , enable_mh=yes)
if test "$enable_mh" = yes; then
  MH_SUPPORT="#define MH_SUPPORT"
else
  MH_SUPPORT="#undef MH_SUPPORT"
fi
AC_SUBST(MH_SUPPORT)

AC_ARG_ENABLE(maildir, [  --disable-maildir	  disable MailDir support], , enable_maildir=yes)
if test "$enable_maildir" = yes; then
  MAILDIR_SUPPORT="#define MAILDIR_SUPPORT"
else
  MAILDIR_SUPPORT="#undef MAILDIR_SUPPORT"
fi
AC_SUBST(MAILDIR_SUPPORT)

AC_ARG_ENABLE(pop3, [  --disable-pop3	  disable POP3 support], , enable_pop3=yes)
if test "$enable_pop3" = yes; then
  POP3_SUPPORT="#define POP3_SUPPORT"
else
  POP3_SUPPORT="#undef POP3_SUPPORT"
fi
AC_SUBST(POP3_SUPPORT)

AC_ARG_ENABLE(imap, [  --disable-imap	  disable IMAP4 support], , enable_imap=yes)
if test "$enable_imap" = yes; then
  IMAP_SUPPORT="#define IMAP_SUPPORT"
else
  IMAP_SUPPORT="#undef IMAP_SUPPORT"
fi
AC_SUBST(IMAP_SUPPORT)

AC_ARG_ENABLE(debug, [  --enable-debug	  turn on debugging], , enable_debug=no)
if test "$enable_debug" = yes; then
  DDEBUG="#define DEBUG"
else
  DDEBUG="#undef DEBUG"
fi
AC_SUBST(DDEBUG)


dnl
dnl  Sun/Solaris need the following
dnl
AC_CHECK_LIB(nsl, gethostbyname)
AC_CHECK_LIB(socket, socket)


dnl
dnl  check for essential libraries
dnl
AC_CHECK_LIB(X11, XOpenDisplay)
AC_CHECK_LIB(Xext, XShapeCombineMask)
AC_CHECK_LIB(Xt, XtAppInitialize)
AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData, , , $LIBS)
AC_CHECK_LIB(PropList, PLGetProplistWithPath, , , $LIBS)


dnl
dnl  check for other (unused) libraries
dnl
dnl AC_CHECK_LIB(wraster, RDestroyImage, , , $LIBS)
dnl AC_CHECK_LIB(WINGs, WMAppSetMainMenu, , , $LIBS)
dnl AC_CHECK_LIB(WMaker, WMAppSetMainMenu)
dnl AC_CHECK_LIB(gif, DGifOpenFileName, , , $LIBS)
dnl AC_CHECK_LIB(jpeg, jpeg_read_scanlines, , , $LIBS)
dnl AC_CHECK_LIB(tiff, TIFFOpen, , , $LIBS)
dnl AC_CHECK_LIB(z, deflateReset)
dnl AC_CHECK_LIB(png, png_get_valid, , , $LIBS)


dnl
dnl  check for header files
dnl
AC_HEADER_STDC
AC_HEADER_DIRENT
AC_CHECK_HEADERS(limits.h strings.h unistd.h)


dnl
dnl  check for typedef's, structures, and other compiler characteristics
dnl
AC_TYPE_OFF_T
AC_TYPE_PID_T
AC_TYPE_SIZE_T


dnl
dnl  check for library functions
dnl
AC_TYPE_SIGNAL
AC_FUNC_VPRINTF
AC_CHECK_FUNCS(socket strstr)


dnl
dnl create Makefile
dnl
AC_OUTPUT(Makefile src/config.h src/wmutil.c src/Makefile Defaults/Makefile \
          Anims/Makefile Anims/NeXT/Makefile Anims/asmail/Makefile \
          Anims/e/Makefile Anims/monitor-e/Makefile Sounds/Makefile)