dnl Process this file with autoconf to produce a configure script.
AC_INIT(ltl/marray.h)
AC_CANONICAL_SYSTEM

AM_INIT_AUTOMAKE(ltl, 1.7.10)
AM_CONFIG_HEADER(ltl/acconfig.h)

dnl Checks for C++ compiler and deal with compiler options
AC_LANG_CPLUSPLUS
test ".$CXXFLAGS" = "." && CXXFLAGS=""
AC_PROG_CXX

BASECXX=`basename $CXX`

case "$BASECXX" in
  g++)
    CXXFLAGS_1="-O3 -Wall -ffast-math -fstrict-aliasing" 
    case "$target" in
       *darwin*)
       case "$target" in
            *powerpc*)
	    CXXFLAGS_1=$CXXFLAGS_1" -mcpu=G4 -mtune=G4 -Wno-long-double -mdynamic-no-pic"
       	    ;;
	    *i386*)
	    CXXFLAGS_1=$CXXFLAGS_1" -march=i686 -mtune=i686"
	    ;;
       esac
       ;;
       *x86_64*)
       CXXFLAGS_1=$CXXFLAGS_1" -march=k8"
       ;;
    esac
    test ".$CXXFLAGS" = "." && CXXFLAGS=$CXXFLAGS_1
    ;;

  xlC*)
    test ".$CXXFLAGS" = "." && CXXFLAGS="-g -O3 -Q -qansialias -qstrict" 
    ;;
  CC)
    case "$target" in
       *solaris*)
       CXXEXTFLAGS=`fpversion | grep Use | cut -d \" -f 2`
       test ".$CXXFLAGS" = "." && CXXFLAGS="-g -fast -xalias_level=compatible $CXXEXTFLAGS"
     ;;
    esac
    ;;
  icc)
    test ".$CXXFLAGS" = "." && CXXFLAGS="-g -O3 -ansi_alias -Ob1 -restrict -ip"
    ;;
 esac

echo "***************************************"
echo "Compiler: " $CXX $CXXFLAGS
echo "***************************************"

dnl check for large file support
AC_SYS_LARGEFILE_SENSITIVE

AC_PROG_CXXCPP
AC_PROG_RANLIB

dnl Checks for libraries.

dnl compiler characteristics.
AC_LANG_CPLUSPLUS
AC_CXX_NAMESPACES
AC_C_LONG_DOUBLE
AC_CXX_NCEG_RESTRICT
AC_C_BIGENDIAN
AC_NEED_STDINT_H(ltl/misc/stdint_hack.h)

dnl Checks for header files.
dnl AC_LANG_C
AC_HEADER_STDC
AC_CHECK_HEADERS(math.h fcntl.h string.h unistd.h float.h sys/mman.h)
AC_CHECK_FUNCS(mmap mktime strftime getrusage snprintf)
dnl AC_LANG_CPLUSPLUS

AC_CXX_HAVE_STL
AC_CHECK_HEADERS(strstream sstream ios limits)
AC_CXX_HAVE_IEEE_MATH
AC_CXX_HAVE_NUMERIC_LIMITS

dnl Checks for typedefs and structures.
AC_TYPE_SIZE_T
AC_STRUCT_TM

dnl check compiler for reasonalbe template support.
AC_CXX_ENUM_COMPUTATIONS
AC_CXX_FULL_SPECIALIZATION_SYNTAX
AC_CXX_PARTIAL_SPECIALIZATION
AC_CXX_MEMBER_TEMPLATES
AC_CXX_MEMBER_TEMPLATES_OUTSIDE_CLASS
AC_CXX_TEMPLATE_QUALIFIED_RETURN_TYPE
AC_CXX_PARTIAL_ORDERING

dnl append ltl/ to includedir to have all headers in a subdirectory
dnl includedir=${includedir}/ltl
echo The ltl header files will be installed in ${includedir}
echo The ltl library will be installed in ${libdir}

AC_OUTPUT(Makefile ltl/Makefile doc/Makefile test/Makefile)