#!/usr/bin/perl
# f90_count - count physical lines of code in Fortran 90.
# Usage: f90_count [-f file] [list_of_files]
#  file: file with a list of files to count (if "-", read list from stdin)
#  list_of_files: list of files to count
#  -f file or list_of_files can be used, or both

# Ignores comment-only lines (where first nonblank character = !).
# Lines beginning with !hpf$ or !omp$ are not comments lines.

$total_sloc = 0;

# Do we have "-f" (read list of files from second argument)?
if (($#ARGV >= 1) && ($ARGV[0] eq "-f")) {
  # Yes, we have -f
  if ($ARGV[1] eq "-") {
    # The list of files is in STDIN
    while (<STDIN>) {
      chomp ($_);
      &count_file ($_);
    }
  } else {
    # The list of files is in the file $ARGV[1]
    open (FILEWITHLIST, $ARGV[1]) || die "Error: Could not open $ARGV[1]\n";
    while (<FILEWITHLIST>) {
      chomp ($_);
      &count_file ($_);
    }
    close FILEWITHLIST;
  }
  shift @ARGV; shift @ARGV;
}
# Process all (remaining) arguments as file names
while ($file = shift @ARGV) {
  &count_file ($file);
}

print "Total:\n";
print "$total_sloc\n";

sub count_file {
  my ($file) = @_;
  my $sloc = 0;

  open (FILE, $file);
  while (<FILE>) {
    # a comment is              m/^\s*!/
    # an empty line is          m/^\s*$/
    # a HPF statement is        m/^\s*!hpf\$/i
    # an Open MP statement is   m/^\s*!omp\$/i
    if (! m/^(\s*!|\s*$)/ || m/^\s*!(hpf|omp)\$/i) {$sloc++;}
  }
  print "$sloc $file\n";
  $total_sloc += $sloc;
  $sloc = 0;
  close (FILE);
}