dnl $Id: configure.ac,v 1.9 2006/08/07 15:01:28 mickey Exp $
dnl
dnl Process this file with autoconf 2.59 or later to produce ./configure
dnl ====================================================================

m4_include([version.m4])

AC_INIT(VC_PACKAGE, VC_VERSION, VC_BUGADDR, VC_TARNAME)
AC_PREREQ(2.59)
AC_REVISION($Revision: 1.9 $)
AC_CONFIG_SRCDIR([config.h.in])
AC_CONFIG_HEADER([config.h])
AC_CONFIG_LIBOBJ_DIR([lib])

AC_DEFINE_UNQUOTED(PACKAGE_RELDATE, "VC_RELDATE", The package release date)

dnl
dnl Checks for programs
dnl

AC_VCHAT_CFLAGS_CHECK
AC_PROG_CC
AC_VCHAT_GCC_WALL_CHECK
AC_PROG_GCC_TRADITIONAL

AC_PROG_INSTALL
AC_PATH_PROG(RM, rm)
AC_PATH_PROG(ECHO, echo)
AC_PATH_PROG(MKDEP, mkdep)
AC_PATH_PROG(MAKEDEPEND, makedepend)
AC_PATH_PROG(UNAME, uname)

AC_VCHAT_DEPEND_CHECK

dnl
dnl Checks for libraries
dnl

AC_CHECK_LIB(wsock32, main)
AC_CHECK_LIB(socket, socket)
AC_CHECK_LIB(nsl, gethostbyname)

dnl
dnl Checks for header files
dnl

AC_CHECK_HEADERS([stddef.h stdarg.h varargs.h ctype.h])
AC_CHECK_HEADERS([paths.h limits.h errno.h pwd.h])
AC_HEADER_TIME
AC_CHECK_HEADERS([sys/time.h])
AC_CHECK_HEADERS([syslog.h signal.h setjmp.h fcntl.h])
AC_CHECK_HEADERS([sys/uio.h sys/select.h sys/mman.h])
AC_CHECK_HEADERS([sys/socket.h netinet/in.h arpa/inet.h sys/un.h netdb.h])
AC_CHECK_HEADERS([termios.h sgtty.h sys/ioctl.h sys/resource.h])
AC_CHECK_HEADERS([sys/sysctl.h sys/systeminfo.h sys/utsname.h sys/param.h])

dnl
dnl Checks for declarations
dnl

AC_CHECK_DECLS([sys_signame, sys_siglist],,,
[#include <signal.h>
#if HAVE_UNISTD_H
#  include <unistd.h>
#endif
])

dnl
dnl Checks for structures
dnl

AC_STRUCT_TM

dnl
dnl Checks for typedefs
dnl

AC_TYPE_UID_T
AC_TYPE_SIZE_T
AC_CHECK_TYPE(ssize_t, int)
AC_CHECK_TYPE(u_char, unsigned char)
AC_CHECK_TYPE(off_t, int)
AC_CHECK_TYPE(socklen_t, int)

dnl
dnl Checks for library functions
dnl

AC_FUNC_SETVBUF_REVERSED
AC_FUNC_MALLOC
AC_FUNC_REALLOC
AC_FUNC_MMAP
AC_FUNC_SELECT_ARGTYPES
AC_FUNC_STRFTIME
AC_FUNC_VPRINTF

AC_CHECK_FUNCS([bcmp bcopy bzero memcmp memcpy memset])
AC_CHECK_FUNCS([strchr strrchr index rindex strsep strtol])
AC_CHECK_FUNCS([snprintf vsnprintf strerror strsignal])
AC_CHECK_FUNCS([daemon syslog gettimeofday])
AC_CHECK_FUNCS([sigaction sigvec setitimer alarm setjmp])
AC_CHECK_FUNCS([mmap madvise munmap])
AC_CHECK_FUNCS([select socket inet_ntoa inet_aton])
AC_CHECK_FUNCS([gethostbyaddr gethostbyname herror hstrerror])
AC_CHECK_FUNCS([sysctl sysinfo uname getloadavg])

dnl
dnl Checks for system services
dnl

dnl
dnl Check for additional features
dnl

AC_VCHAT_READLINE_CHECK
AC_VCHAT_UXDOMAIN_CHECK
AC_VCHAT_OSTYPE_CHECK
AC_VCHAT_BASEDIR_CHECK

dnl
dnl Output files
dnl

AC_CONFIG_FILES([stamp-h], [echo timestamp > stamp-h])
AC_CONFIG_FILES([Makefile
		 src/Makefile
		 src/vserver/Makefile
		 src/vchatctl/Makefile
		 man/Makefile
 		 man/vserver.8
		 man/vchatctl.8])
AC_OUTPUT