# Diese Datei wurde mit dem qmake-Manager von KDevelop erstellt. 
# ------------------------------------------- 
# Unterverzeichnis relativ zum Projektverzeichnis: ./src
# Das Target ist Projekt im Unterverzeichnis 

SUBDIRS += core \
           basicelements \
           worldengine \
           clientengine \
           demo \
           god \
           guniverse \
           guniverseclient 
TEMPLATE = subdirs
CONFIG += release \
warn_on

# some parts can be disabled, for example if you want a server-only install
# you would set G_NO_CLIENT, G_NO_GOD and G_NO_DEMO.
# KDE is required for the client and GOD, the server is qt-only.

NO_CLIENT = $$(G_NO_CLIENT)
!isEmpty( NO_CLIENT ) {
  message("Disabling guniverseclient")
  SUBDIRS -= guniverseclient
}
NO_SERVER = $$(G_NO_SERVER)
!isEmpty( NO_SERVER ) {
  message("Disabling guniverse server")
  SUBDIRS -= guniverse
}
NO_GOD = $$(G_NO_GOD)
!isEmpty( NO_GOD ) {
  message("Disabling god")
  SUBDIRS -= god
}
NO_DEMO = $$(G_NO_DEMO)
!isEmpty( NO_DEMO ) {
  message("Disabling demo")
  SUBDIRS -= demo
}