#!/usr/bin/perl

########################################################################
# metaf2xml.pl -- wrapper script for parsing and printing reports
#
# copyright (c) metaf2xml 2006-2007
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License as
# published by the Free Software Foundation; either version 2 of the
# License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA
########################################################################

########################################################################
# some things strictly perl
########################################################################
use strict;
use warnings;

=head1 NAME

metaf2xml.pl -- wrapper script for parsing and printing reports

=head1 SYNOPSIS

  metaf2xml.pl [C<options>]... [C<msg>]...

=head1 DESCRIPTION

  Note: This manual is valid for version 1.29 of metaf2xml.

This script is an example interface to the modules C<metaf2xml::parser> and
C<metaf2xml::XML>. Messages (per default: METAR) can be given on the command
line (in single or double quotes) or read from C<STDIN>, one message per line.

C<metaf2xml.pl> expects complete messages, as specified by WMO-Nr. 306,
without additions or contractions as done for distribution (e.g.
the SYNOP section 0 is given only once for several messages,
or a trailing "=" (equal sign)).

It also recognises the keywords B<METAR>, B<TAF>, and B<SYNOP>. If a message
consists only of such a keyword, all messages after it are expected to be of the
corresponding type. The keyword can also be prepended to a message.

=head1 DEPENDENCIES

The modules C<Getopt::Std>, C<metaf2xml::parser>, and C<metaf2xml::XML> are
required.

=head1 OPTIONS

=over

=item -t

given message is a TAF message

=item -s

given message is a SYNOP message

=item -x F<file>

write result as XML to F<filename>

=item -X

with B<-x>, produce XML file with C<<version>> and C<<options>> section, to be
used for the user interface

=item -D

with B<-X>, add DOCTYPE and reference to DTD

=item -S F<filename>

with B<-X>, add reference to stylesheet F<filename>, to be used for the user
interface

=item -O F<options>

with B<-S>, add F<options> to XML file

=back

=head1 EXAMPLES

Parse a METAR message and write the XML section C<<reports>> to C<STDOUT>:

  metaf2xml.pl -x- 'YUDO 090600Z 00000KT CAVOK 22/15 Q1021 NOSIG'

Parse several METAR, TAF, and SYNOP messages and write the XML to the file
F<metar-taf-synop.xml>:

  metaf2xml.pl -x metar-taf-synop.xml <<EOF
  METAR
  SBGL 091800Z 14008KT 9999 FEW020 BKN035 23/15 Q1013
  TAF
  SBGL 091550Z 091818 20015KT 8000 BKN020 PROB40 2024 4000 RA BKN015 BECMG 0002 24005KT BKN015 TEMPO 0210 4000 RA BR BKN010 BECMG 1113 20010KT 4000 RA BR TX22/19Z TN18/08Z
  METAR
  KJFK 091751Z 34013KT 10SM SCT038 21/11 A2952
  TAF
  KJFK 091425Z 091412 34012KT P6SM OVC025 TEMPO 1416 SCT025 FM1600 32013G18KT P6SM SCT025 BKN040 FM1800 31010KT P6SM SCT050 FM2200 28010KT P6SM SKC
  METAR
  RJTT 091830Z 34005KT CAVOK 14/09 Q1020 RMK A3012
  TAF
  RJTT 091500Z 091524 30004KT 9999 FEW020
  RJTT 091500Z 100018 05005KT 9999 FEW030 BECMG 0003 14006KT BECMG 0912 30010KT
  SYNOP
  AAXX 17124 83746 21558 33602 10263 20218 40171 51014 70596 82530 333 20227 69924
  AAXX 17124 74486 12566 63616 10067 20022 39972 49982 51028 69931 91151 333 10128 20056 70025 91021 555 91712
  EOF

=head1 SEE ALSO

=begin html

<a href=parser.pm.html>metaf2xml::parser(3pm)</a>,
<a href=XML.pm.html>metaf2xml::XML(3pm)</a>,
<a href=metaf.pl.html>metaf(1)</a>, <!--

=end html

B<metaf2xml::parser>(3pm),
B<metaf2xml::XML>(3pm),
B<metaf>(1),

=for html -->

L<http://metaf2xml.sourceforge.net/>

=head1 COPYRIGHT, LICENSE, DISCLAIMER

copyright (c) 2006-2007 metaf2xml @ L<http://metaf2xml.sourceforge.net/>

This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License as
published by the Free Software Foundation; either version 2 of the
License, or (at your option) any later version.

This program is distributed in the hope that it will be useful, but
WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
General Public License for more details.

You should have received a copy of the GNU General Public License
along with this program; if not, write to the Free Software
Foundation, 59 Temple Place, Suite 330, Boston, MA 02111-1307, USA

=cut

use Getopt::Std;

# path may be changed by install
use lib '/opt/metaf2xml/lib'; # METAF2XML_LIB
use metaf2xml::parser qw(parseReport);
use metaf2xml::XML qw(startXML printReport finishXML);

my ($VERSION_ID, %report_data, %opts, $is_taf, $is_synop, $output);

$VERSION_ID = 'metaf2xml.pl: $Id: metaf2xml.pl,v 1.16 2007/09/11 13:04:33 metaf2xml Exp $';

sub go {
    my $msg = shift;

    if ($msg eq 'METAR') {
        $is_taf = 0;
        $is_synop = 0;
        return;
    }
    if ($msg eq 'TAF') {
        $is_taf = 1;
        $is_synop = 0;
        return;
    }
    if ($msg eq 'SYNOP') {
        $is_taf = 0;
        $is_synop = 1;
        return;
    }

    %report_data = parseReport $msg, $is_taf, $is_synop;
    printReport \%report_data if exists $opts{x};
}

sub usage {
    print STDERR
          (shift)
        . "Usage: metaf2xml.pl [ <options> ] [ <message> ]\n"
        . "  Options:\n"
        . "  -t            given message is a TAF message\n"
        . "  -s            given message is a SYNOP message\n"
        . "  -x <filename> write result as XML to <filename>\n"
        . "  -X            with -x, produce XML file with <version> and <options> section\n"
        . "  -D            with -X, add DOCTYPE and reference to DTD\n"
        . "  -S <filename> with -X, add reference to stylesheet <filename>\n"
        . "  -O <options>  with -S, add <options> to XML file\n";
    exit 1;
}

# get and check options
usage '' unless getopts('tsx:XDS:O:', \%opts);

# check dependencies of options
usage "option -X requires option -x\n" if exists $opts{X} && !exists $opts{x};
usage "option -D requires option -X\n" if exists $opts{D} && !exists $opts{X};
usage "option -S requires option -X\n" if exists $opts{S} && !exists $opts{X};
usage "option -O requires option -S\n" if exists $opts{O} && !exists $opts{S};

$is_taf      = exists $opts{t};
$is_synop    = exists $opts{s};

startXML \%opts, [ $VERSION_ID, $metaf2xml::parser::VERSION_ID ]
    if exists $opts{x};

if ($#ARGV >= 0) {
    for (@ARGV) {
        for (split /\n/, $_) {
            go $_;
        }
    }
} else {
    while (<STDIN>) {
        chomp();
        go $_;
    }
}

finishXML;