dnl AC_CHECK_HAVE_TYPE(TYPE)
AC_DEFUN(AC_CHECK_HAVE_TYPE,
[AC_REQUIRE([AC_HEADER_STDC])dnl
AC_MSG_CHECKING(for $1)
AC_CACHE_VAL(ac_cv_type_$1,
[
AC_EGREP_CPP(changequote(<,>)<[ 	]$1[ 	]*;>changequote([,]),
[#include <sys/types.h>
#if STDC_HEADERS
#include <stdlib.h>
#endif], ac_cv_type_$1=yes, ac_cv_type_$1=no)])dnl
AC_MSG_RESULT($ac_cv_type_$1)
if test $ac_cv_type_$1 = yes; then
changequote(<,>)dnl
  ac_type=HAVE_`echo $1 | tr '[a-z]' '[A-Z]'`
changequote([,])dnl
  AC_DEFINE_UNQUOTED($ac_type)
fi
])

dnl MHW_MOD_CHECK()
dnl $1 - name of module being searched for

AC_DEFUN(MHW_MOD_CHECK,
[AC_MSG_CHECKING(for module $1)
if test -d "$1"; then
  found="$1"
else
  found=no
  for dir in $srcdir/$1*
  do
    if test -d $dir; then
      case $found in
      no)
        found=`basename $dir`
        ;;
      *)
        AC_MSG_WARN(there are multiple directories beginning with \`\`$1'')
        AC_MSG_WARN(configure can't tell which one to configure)
        ;;
      esac
    fi
  done
fi
case $found in
no)
  ;;
*)
  mod_subdirs="$mod_subdirs $found"
  ;;
esac
AC_MSG_RESULT($found)
])