dnl --------------------------------
dnl Initialization macros.
dnl --------------------------------

AC_INIT(bakery/bakery.h)
# AC_CONFIG_AUX_DIR(scripts) #Breaks intltools for some reason.
AC_CONFIG_HEADERS(config.h bakery/bakeryconfig.h)

dnl -----------------------------------------------
dnl Package name and version number (user defined)
dnl -----------------------------------------------

GENERIC_LIBRARY_NAME=bakery

#release versioning
GENERIC_MAJOR_VERSION=2
GENERIC_MINOR_VERSION=4
GENERIC_MICRO_VERSION=3

#shared library versioning
GENERIC_LIBRARY_VERSION=1:0:0
#                        | |
#                +------+ | +---+
#                |        |     |
#             current:revision:age
#                |        |     |
#                |        |     +- increment if interfaces have been added
#                |        |        set to zero if interfaces have been removed
#                                  or changed
#                |        +- increment if source code has changed
#                |           set to zero if current is incremented
#                +- increment if interfaces have been added, removed or changed


dnl --------------------------------
dnl Package name and version number
dnl --------------------------------

AC_SUBST(GENERIC_LIBRARY_VERSION)

PACKAGE=$GENERIC_LIBRARY_NAME
AC_SUBST(GENERIC_LIBRARY_NAME)

GENERIC_VERSION=$GENERIC_MAJOR_VERSION.$GENERIC_MINOR_VERSION.$GENERIC_MICRO_VERSION
GENERIC_RELEASE=$GENERIC_MAJOR_VERSION.$GENERIC_MINOR_VERSION
AC_SUBST(GENERIC_RELEASE)
AC_SUBST(GENERIC_VERSION)

AC_DEFINE_UNQUOTED(GENERIC_MAJOR_VERSION, $GENERIC_MAJOR_VERSION, "define GENERIC_MAJOR_VERSION")
AC_DEFINE_UNQUOTED(GENERIC_MINOR_VERSION, $GENERIC_MINOR_VERSION, "define GENERIC_MINOR_VERSION")
AC_DEFINE_UNQUOTED(GENERIC_MICRO_VERSION, $GENERIC_MICRO_VERSION, "define GENERIC_MICRO_VERSION")

VERSION=$GENERIC_VERSION

AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)

dnl -----------------------------------------------
dnl Checks for programs:
dnl -----------------------------------------------

AC_PROG_CC
AC_PROG_CXX
AM_PROG_LIBTOOL
AM_SANITY_CHECK


dnl -----------------------------------------------
dnl Checks for libraries:
dnl -----------------------------------------------

REQUIRED_LIBRARIES="gtkmm-2.4 >= 2.10.0 gconfmm-2.6 >= 2.6.0 libglademm-2.4 >= 2.4.0 libxml++-2.6 >= 2.8.0 gnome-vfsmm-2.6 >= 2.6.0"

AC_ARG_ENABLE([maemo],
	AC_HELP_STRING([--enable-maemo],
	[build with support for the maemo platform]),
	[enable_maemo=$enableval],
	[enable_maemo=no])

if test "$enable_maemo" = "yes"; then
	AC_DEFINE([BAKERY_MAEMO_ENABLED], 1, [Whether to enable support for the maemo platform])
	REQUIRED_LIBRARIES="$REQUIRED_LIBRARIES hildonmm hildon-fmmm"
fi

PKG_CHECK_MODULES(BAKERY, $REQUIRED_LIBRARIES)
AC_SUBST(BAKERY_CFLAGS)
AC_SUBST(BAKERY_LIBS)

# Check for gtkmm 2.10 to enable additional features
PKG_CHECK_MODULES(GTKMM, gtkmm-2.4 >= 2.10.0, [gtkmm_ver=ver2_10], [gtkmm_ver=ver2_6])

if test $gtkmm_ver = ver2_10; then
	AC_DEFINE([GTKMM_GEQ_2_10], 1, [Define if Gtkmm version is 2.10 or greater])
fi

dnl I18n
GETTEXT_PACKAGE=$PACKAGE
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", "define GETTEXT_PACKAGE")
AC_SUBST(GETTEXT_PACKAGE)

dnl List all available languages here
ALL_LINGUAS="ar bg ca de dz el en_CA en_GB es fi fr gl hu ja lt mk nb ne nl oc pl pt_BR ru rw sk sl sq sv uk vi zh_CN zh_TW"
AM_GLIB_GNU_GETTEXT
AC_PROG_INTLTOOL(0.25)

# Dummy conditional just to make automake-1.4 happy.
# We need an always-false condition in docs/Makefile.am.
AM_CONDITIONAL(BAKERY_FALSE,[false])


dnl -----------------------------------------------
dnl Generates Makefile's, configuration files and scripts
dnl -----------------------------------------------

AC_OUTPUT(Makefile 
          bakery-2.4.pc 
          bakery/Makefile 
          bakery/App/Makefile
          bakery/Configuration/Makefile
          bakery/Document/Makefile
          bakery/Utilities/Makefile
          bakery/View/Makefile 
          docs/Makefile 
          docs/reference/Makefile

          examples/Makefile
            examples/Configuration/Makefile
              examples/Configuration/ConfClient/Makefile
              examples/Configuration/Dialog_Preferences/Makefile
            examples/WithoutDoc/Makefile
            examples/WithDoc/Makefile
            examples/WithDocView/Makefile
            examples/WithDocViewComposite/Makefile
            examples/WithXmlDoc/Makefile
            examples/WithXmlDocGlade/Makefile
            examples/Utilities/Makefile
              examples/Utilities/BusyCursor/Makefile

          po/Makefile.in
          bakery.spec
)